
theorem Th124:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`2=d & p2`1=b
& p3`2= c & p4`2= c & a <=p1`1 & p1`1<=b & c <=p2`2 & p2`2<=d & a<p4`1 & p4`1<
p3`1 & p3`1<=b & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one
  & g is continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) &
  rng g c= closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`2=d and
A4: p2`1=b and
A5: p3`2= c and
A6: p4`2= c and
A7: a <=p1`1 and
A8: p1`1<=b and
A9: c <=p2`2 and
A10: p2`2<=d and
A11: a<p4`1 and
A12: p4`1<p3`1 and
A13: p3`1<=b and
A14: f.0=p1 and
A15: f.1=p3 and
A16: g.0=p2 and
A17: g.1=p4 and
A18: f is continuous one-to-one and
A19: g is continuous one-to-one and
A20: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A21: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A22: -1 <=((g2).O)`2 by A1,A2,A4,A9,A10,A16,Th66;
A23: ((g2).O)`2<=1 by A1,A2,A4,A9,A10,A16,Th66;
A24: g2 is continuous one-to-one by A1,A2,A19,Th53;
A25: ((g2).I)`2= -1 by A2,A6,A17,Th57;
A26: ((g2).O)`1= 1 by A1,A4,A16,Th56;
A27: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A21,Th52;
  d-c >0 by A2,XREAL_1:50;
  then
A28: C >0 by XREAL_1:139;
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A29: p3`1 >a by A11,A12,XXREAL_0:2;
  then
A30: ((f2).I)`1<=1 by A1,A13,A15,Th64;
A31: ((f2).I)`2= -1 by A2,A5,A15,Th57;
A32: ((f2).O)`2= 1 by A2,A3,A14,Th55;
A33: f2 is continuous one-to-one by A1,A2,A18,Th53;
  set x = the Element of rng f2 /\ rng g2;
A34: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then
A35: h.p4=g2.I by A17,FUNCT_1:13;
  b-a>0 by A1,XREAL_1:50;
  then
A36: A >0 by XREAL_1:139;
  then
A37: (h.p4)`1<(h.p3)`1 by A12,A28,Th50;
  p4`1<b by A12,A13,XXREAL_0:2;
  then
A38: -1<((g2).I)`1 by A1,A2,A6,A11,A17,Th66;
  h is being_homeomorphism by A36,A28,Th50;
  then
A39: h is one-to-one by TOPS_2:def 5;
A40: (f.I)`2= c by A5,A15;
  then
A41: -1 <=((f2).O)`1 by A1,A7,A8,A13,A14,A15,A29,Th64;
A42: ((f2).O)`1<=1 by A1,A7,A8,A13,A14,A15,A29,A40,Th64;
A43: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A20,Th52;
A44: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then h.p3=f2.I by A15,FUNCT_1:13;
  then rng f2 meets rng g2 by A37,A35,A33,A32,A31,A41,A42,A30,A43,A24,A26,A25
,A22,A23,A38,A27,Th42,JGRAPH_6:79;
  then
A45: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A46: z2 in dom g2 and
A47: x=g2.z2 by FUNCT_1:def 3;
A48: x=h.(g.z2) by A34,A46,A47,FUNCT_1:13;
A49: g.z2 in rng g by A34,A46,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A46,FUNCT_2:5;
  then
A50: g.z2 in dom h by FUNCT_2:def 1;
  x in rng f2 by A45,XBOOLE_0:def 4;
  then consider z1 being object such that
A51: z1 in dom f2 and
A52: x=f2.z1 by FUNCT_1:def 3;
A53: f.z1 in rng f by A44,A51,FUNCT_1:def 3;
  f.z1 in the carrier of TOP-REAL 2 by A51,FUNCT_2:5;
  then
A54: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A44,A51,A52,FUNCT_1:13;
  then f.z1=g.z2 by A48,A54,A50,A39,FUNCT_1:def 4;
  hence thesis by A53,A49,XBOOLE_0:3;
end;
