reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th125:
  for cn being Real, K0,B0 being Subset of TOP-REAL 2, f being
Function of (TOP-REAL 2)|K0,(TOP-REAL 2)|B0 st -1<cn & cn<1 & f=(cn-FanMorphS)|
  K0 & B0=NonZero TOP-REAL 2 & K0={p: p`2>=0 & p<>0.TOP-REAL 2} holds f is
  continuous
proof
  let cn be Real,K0,B0 be Subset of TOP-REAL 2,
f be Function of (TOP-REAL 2)|
  K0,(TOP-REAL 2)|B0;
  set sn=sqrt(1-cn^2);
  set p0=|[cn,sn]|;
A1: p0`2=sn by EUCLID:52;
  assume
A2: -1<cn & cn<1 & f=(cn-FanMorphS)|K0 & B0=NonZero TOP-REAL 2 & K0={p:
  p`2>=0 & p<>0.TOP-REAL 2};
  then cn^2<1^2 by SQUARE_1:50;
  then
A3: 1-cn^2>0 by XREAL_1:50;
  then sn>0 by SQUARE_1:25;
  then p0 in K0 by A2,A1,JGRAPH_2:3;
  then reconsider K1=K0 as non empty Subset of TOP-REAL 2;
  p0`2>0 by A1,A3,SQUARE_1:25;
  then not p0 in {0.TOP-REAL 2} by JGRAPH_2:3,TARSKI:def 1;
  then reconsider D=B0 as non empty Subset of TOP-REAL 2 by A2,XBOOLE_0:def 5;
A4: K1 c= D
  proof
    let x be object;
    assume x in K1;
    then consider p2 being Point of TOP-REAL 2 such that
A5: p2=x and
    p2`2>=0 and
A6: p2<>0.TOP-REAL 2 by A2;
    not p2 in {0.TOP-REAL 2} by A6,TARSKI:def 1;
    hence thesis by A2,A5,XBOOLE_0:def 5;
  end;
  for p being Point of (TOP-REAL 2)|K1,V being Subset of (TOP-REAL 2)|D
st f.p in V & V is open holds ex W being Subset of (TOP-REAL 2)|K1 st p in W &
  W is open & f.:W c= V
  proof
    let p be Point of (TOP-REAL 2)|K1,V be Subset of (TOP-REAL 2)|D;
    assume that
A7: f.p in V and
A8: V is open;
    consider V2 being Subset of TOP-REAL 2 such that
A9: V2 is open and
A10: V2 /\ [#]((TOP-REAL 2)|D)=V by A8,TOPS_2:24;
    reconsider W2=V2 /\ [#]((TOP-REAL 2)|K1) as Subset of (TOP-REAL 2)| K1;
A11: [#]((TOP-REAL 2)|K1)=K1 by PRE_TOPC:def 5;
    then
A12: f.p=(cn-FanMorphS).p by A2,FUNCT_1:49;
A13: f.:W2 c= V
    proof
      let y be object;
      assume y in f.:W2;
      then consider x being object such that
A14:  x in dom f and
A15:  x in W2 and
A16:  y=f.x by FUNCT_1:def 6;
      f is Function of (TOP-REAL 2)|K1,(TOP-REAL 2)|D;
      then dom f= K1 by A11,FUNCT_2:def 1;
      then consider p4 being Point of TOP-REAL 2 such that
A17:  x=p4 and
A18:  p4`2>=0 and
      p4<>0.TOP-REAL 2 by A2,A14;
A19:  p4 in V2 by A15,A17,XBOOLE_0:def 4;
      p4 in [#]((TOP-REAL 2)|K1) by A14,A17;
      then p4 in D by A4,A11;
      then
A20:  p4 in [#]((TOP-REAL 2)|D) by PRE_TOPC:def 5;
      f.p4=(cn-FanMorphS).p4 by A2,A11,A14,A17,FUNCT_1:49
        .=p4 by A18,Th113;
      hence thesis by A10,A16,A17,A19,A20,XBOOLE_0:def 4;
    end;
    p in the carrier of (TOP-REAL 2)|K1;
    then consider q being Point of TOP-REAL 2 such that
A21: q=p and
A22: q`2>=0 and
    q <>0.TOP-REAL 2 by A2,A11;
    (cn-FanMorphS).q=q by A22,Th113;
    then p in V2 by A7,A10,A12,A21,XBOOLE_0:def 4;
    then
A23: p in W2 by XBOOLE_0:def 4;
    W2 is open by A9,TOPS_2:24;
    hence thesis by A23,A13;
  end;
  hence thesis by JGRAPH_2:10;
end;
