reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;
reserve f for clockwise_oriented non constant standard
  special_circular_sequence;
reserve p for Point of TOP-REAL 2;

theorem Th109:
  for C being compact Subset of TOP-REAL 2 for WH being connected
  Subset of TOP-REAL 2 st WH is non bounded & WH misses C holds WH c= UBD C
proof
  let C be compact Subset of TOP-REAL 2;
  let WH be connected Subset of TOP-REAL 2;
  assume that
A1: WH is non bounded and
A2: WH misses C;
A3: WH meets UBD C
  proof
    (BDD C) \/ (UBD C) = C` & [#]the carrier of TOP-REAL 2 = C \/ C` by Th18,
SUBSET_1:10;
    then
A4: WH c= (UBD C) \/ BDD C by A2,XBOOLE_1:73;
    assume
A5: WH misses UBD C;
    BDD C is bounded by Th90;
    hence thesis by A1,A5,A4,RLTOPSP1:42,XBOOLE_1:73;
  end;
  WH c= C` by A2,SUBSET_1:23;
  hence thesis by A3,Th108,GOBOARD9:4;
end;
