
theorem Th126:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`2=d & p2`2=
  c & p3`2= c & p4`2= c & a <=p1`1 & p1`1<=b & a<p4`1 & p4`1<p3`1 & p3`1<p2`1 &
p2`1<=b & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one & g is
continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) & rng g c=
  closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`2=d and
A4: p2`2= c and
A5: p3`2= c and
A6: p4`2= c and
A7: a <=p1`1 and
A8: p1`1<=b and
A9: a<p4`1 and
A10: p4`1<p3`1 and
A11: p3`1<p2`1 and
A12: p2`1<=b and
A13: f.0=p1 and
A14: f.1=p3 and
A15: g.0=p2 and
A16: g.1=p4 and
A17: f is continuous one-to-one and
A18: g is continuous one-to-one and
A19: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A20: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A21: p2`1>p4`1 by A10,A11,XXREAL_0:2;
  (g.O)`2= c by A4,A15;
  then
A22: ((g2).I)`1> -1 by A1,A9,A12,A15,A16,A21,Th67;
  d-c >0 by A2,XREAL_1:50;
  then
A23: C >0 by XREAL_1:139;
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A24: b>p3`1 by A11,A12,XXREAL_0:2;
  (g.I)`2= c by A6,A16;
  then
A25: 1 >=((g2).O)`1 by A1,A9,A12,A15,A16,A21,Th67;
A26: ((g2).O)`2= -1 by A2,A4,A15,Th57;
A27: g2 is continuous one-to-one by A1,A2,A18,Th53;
A28: ((f2).O)`2= 1 by A2,A3,A13,Th55;
A29: f2 is continuous one-to-one by A1,A2,A17,Th53;
  set x = the Element of rng f2 /\ rng g2;
A30: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A31: h.p3=f2.I by A14,FUNCT_1:13;
A32: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A20,Th52;
A33: ((g2).I)`2= -1 by A2,A6,A16,Th57;
  b-a>0 by A1,XREAL_1:50;
  then
A34: A >0 by XREAL_1:139;
  then h is being_homeomorphism by A23,Th51;
  then
A35: h is one-to-one by TOPS_2:def 5;
A36: (f.I)`2= c by A5,A14;
A37: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then h.p2=g2.O by A15,FUNCT_1:13;
  then
A38: ((g2).O)`1> ((f2).I)`1 by A11,A34,A23,A31,Th50;
A39: p3`1 > a by A9,A10,XXREAL_0:2;
  then
A40: ((f2).O)`1<=1 by A1,A7,A8,A13,A14,A24,A36,Th64;
A41: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A19,Th52;
A42: ((f2).I)`2= -1 by A2,A5,A14,Th57;
  h.p4=g2.I by A16,A37,FUNCT_1:13;
  then
A43: ((g2).I)`1< ((f2).I)`1 by A10,A34,A23,A31,Th50;
  -1 <=((f2).O)`1 by A1,A7,A8,A13,A14,A39,A24,A36,Th64;
  then rng f2 meets rng g2 by A29,A28,A42,A40,A41,A27,A26,A33,A25,A22,A32,A38
,A43,Th43,JGRAPH_6:79;
  then
A44: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A45: z2 in dom g2 and
A46: x=g2.z2 by FUNCT_1:def 3;
A47: x=h.(g.z2) by A37,A45,A46,FUNCT_1:13;
A48: g.z2 in rng g by A37,A45,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A45,FUNCT_2:5;
  then
A49: g.z2 in dom h by FUNCT_2:def 1;
  x in rng f2 by A44,XBOOLE_0:def 4;
  then consider z1 being object such that
A50: z1 in dom f2 and
A51: x=f2.z1 by FUNCT_1:def 3;
A52: f.z1 in rng f by A30,A50,FUNCT_1:def 3;
  f.z1 in the carrier of TOP-REAL 2 by A50,FUNCT_2:5;
  then
A53: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A30,A50,A51,FUNCT_1:13;
  then f.z1=g.z2 by A47,A53,A49,A35,FUNCT_1:def 4;
  hence thesis by A52,A48,XBOOLE_0:3;
end;
