reserve a, b, d1, d2 for Data-Location,
  il, i1, i2 for Nat,
  I for Instruction of SCM,
  s, s1, s2 for State of SCM,
  T for InsType of the InstructionsF of SCM,
  k,k1 for Nat;

theorem
  (product" JumpParts InsCode SCM-goto k1).1 = NAT
proof
 dom product" JumpParts InsCode SCM-goto k1 = {1}
   by Th9;
  then
A1: 1 in dom product" JumpParts InsCode SCM-goto k1 by TARSKI:def 1;
  hereby
    let x be object;
    assume x in (product" JumpParts InsCode SCM-goto k1).1;
    then x in pi(JumpParts InsCode SCM-goto k1,1) by A1,CARD_3:def 12;
    then consider g being Function such that
A2: g in JumpParts InsCode SCM-goto k1 and
A3: x = g.1 by CARD_3:def 6;
    consider I being Instruction of SCM such that
A4: g = JumpPart I and
A5: InsCode I = InsCode SCM-goto k1 by A2;
    InsCode I = 6 by A5;
    then consider i2 such that
A6: I = SCM-goto i2 by AMI_5:13;
    g = <*i2*> by A4,A6;
    then x = i2 by A3;
    hence x in NAT by ORDINAL1:def 12;
  end;
  let x be object;
  assume x in NAT;
  then reconsider x as Element of NAT;
  JumpPart SCM-goto x = <*x*> & InsCode SCM-goto k1
   = InsCode SCM-goto x;
  then
A7: <*x*> in JumpParts InsCode SCM-goto k1;
  <*x*>.1 = x;
  then x in pi(JumpParts InsCode SCM-goto k1,1) by A7,CARD_3:def 6;
  hence thesis by A1,CARD_3:def 12;
end;
