reserve k,m,n for Nat;
reserve R for commutative Ring,
        p,q for Polynomial of R,
        z0,z1 for Element of R;

theorem Th12:
  for L being add-associative right_zeroed right_complementable distributive
    non empty doubleLoopStr
  for a being Polynomial of L holds
     (~(n * @a)).k = n * (a.k)
proof
  let L be add-associative right_zeroed right_complementable distributive
    non empty doubleLoopStr, a be Polynomial of L;
  set PRR=Polynom-Ring L;
  defpred P[Nat] means (~($1*@a)).k = $1 * (a.k);
  0*@a = 0.PRR by BINOM:12
     .= 0_.L by POLYNOM3:def 10;
  then (~(0*@a)).k = 0.L by ORDINAL1:def 12,FUNCOP_1:7
     .= 0 * (a.k) by BINOM:12;
  then A1:P[0];
  A2:for i being Nat st P[i] holds P[i+1]
  proof
    let i be Nat such that A3: P[i];
    (i+1)*@a = @a +(i*@a) by BINOM:def 3
           .= a+ ~(i*@a) by POLYNOM3:def 10;
    hence (~((i+1)*@a)).k = a.k + ~(i*@a).k by NORMSP_1:def 2
                     .= (i+1) *(a.k) by A3,BINOM:def 3;
  end;
  for i being Nat holds P[i] from NAT_1:sch 2(A1,A2);
  hence thesis;
end;
