
theorem Th12:
  for X being non empty TopSpace, Y being compact non empty
TopSpace, G being open Subset of [:Y, X:] holds { x where x is Point of X : [:
  [#]Y, {x}:] c= G } in the topology of X
proof
  let X be non empty TopSpace, Y be compact non empty TopSpace, G be open
  Subset of [:Y, X:];
  set Q = { x where x is Point of X : [:[#]Y, {x}:] c= G };
  Q c= the carrier of X
  proof
    let q be object;
    assume q in Q;
    then ex x9 being Point of X st q = x9 & [:[#]Y, {x9}:] c= G;
    hence thesis;
  end;
  then reconsider Q as Subset of X;
  defpred P[set] means ex y be set st y in Q & ex S be Subset of X st S = $1 &
  S is open & y in S & S c= Q;
  consider RR be set such that
A1: for x be set holds x in RR iff x in bool Q & P[x] from XFAMILY:sch
  1;
  RR c= bool Q
  by A1;
  then reconsider RR as Subset-Family of Q;
  Q c= union RR
  proof
    let a be object;
    assume a in Q;
    then ex x9 being Point of X st a = x9 & [:[#]Y, {x9}:] c= G;
    then consider R be open Subset of X such that
A2: a in R and
A3: R c= Q by Th11;
    R in RR by A1,A2,A3;
    hence thesis by A2,TARSKI:def 4;
  end;
  then
A4: union RR = Q;
  bool Q c= bool the carrier of X by ZFMISC_1:67;
  then reconsider RR as Subset-Family of X by XBOOLE_1:1;
  RR c= the topology of X
  proof
    let x be object;
    assume x in RR;
    then ex y be set st y in Q & ex S be Subset of X st S = x & S is open & y
    in S & S c= Q by A1;
    hence thesis by PRE_TOPC:def 2;
  end;
  hence thesis by A4,PRE_TOPC:def 1;
end;
