
theorem LM89:
  for A be non empty closed_interval Subset of REAL,
      s be FinSequence of
            R_Normed_Algebra_of_BoundedFunctions
              the carrier of ClstoCmp(A),
      z be FinSequence of REAL,
      g be Function of A,REAL,
      t be Element of A
    st len s = len z
     & g = Sum s
     & for k be Nat st k in dom z
         holds ex sk be Function of A,REAL st
                 sk = s.k & z.k = sk.t
  holds g.t = Sum z
proof
  let A be non empty closed_interval Subset of REAL,
      s be FinSequence of
       R_Normed_Algebra_of_BoundedFunctions
            the carrier of ClstoCmp(A),
      z be FinSequence of REAL,
      g be Function of A,REAL,
      t be Element of A;
  assume
A1: len s = len z & g = Sum s &
    for k be Nat st k in dom z holds
      ex sk be Function of A,REAL st
        sk = s.k & z.k = sk.t;
  defpred P[Nat] means
    for A be non empty closed_interval Subset of REAL,
        s be FinSequence of
         R_Normed_Algebra_of_BoundedFunctions
           the carrier of ClstoCmp(A),
        z be FinSequence of REAL,
        g be Function of A,REAL,
        t be Element of A
      st len s = $1 & len s = len z
        & g = Sum s
        & for k be Nat st k in dom z holds
            ex sk be Function of A,REAL st
              sk = s.k & z.k = sk.t
   holds g.t = Sum z;
  A2: P[0]
  proof
    let A be non empty closed_interval Subset of REAL,
        s be FinSequence of
         R_Normed_Algebra_of_BoundedFunctions
            the carrier of ClstoCmp(A),
        z be FinSequence of REAL,
        g be Function of A,REAL,
        t be Element of A;
    assume that
A3: len s = 0 and
A4: len s = len z and
A5: g = Sum s and
    for k be Nat st k in dom z holds
      ex sk be Function of A,REAL st
        sk = s.k & z.k = sk.t;
    set V = R_Normed_Algebra_of_BoundedFunctions
            the carrier of ClstoCmp(A);
    set AV = the carrier of ClstoCmp(A);
B8: Sum s = 0.V by A3,RLVECT_1:75
         .= AV -->0 by C0SP1:25
         .= A -->0 by Lm1;
    z = <*>REAL by A3,A4;
    hence thesis by B8,FUNCOP_1:7,A5,RVSUM_1:72;
  end;
A9: for n be Nat st P[n] holds P[n+1]
  proof
    let n be Nat;
    assume A10: P[n];
      let A be non empty closed_interval Subset of REAL,
        s be FinSequence of
         R_Normed_Algebra_of_BoundedFunctions
            the carrier of ClstoCmp(A),
        z be FinSequence of REAL,
        g be Function of A,REAL,
        t be Element of A;
      assume that
A11:  len s = n+1 and
A12:  len s = len z and
A13:  g = Sum s and
A14:  for k be Nat st k in dom z holds
        ex sk be Function of A,REAL st
          sk = s.k & z.k = sk.t;
      set V = R_Normed_Algebra_of_BoundedFunctions
            the carrier of ClstoCmp(A);
      set AV = the carrier of ClstoCmp(A);
A15:  A = AV by Lm1;
      set s0=s|n, z0=z|n;
A16:  for k be Nat st k in dom z0 holds
        ex sk be Function of A,REAL st
          sk = s0.k & z0.k = sk.t
      proof
        let k be Nat;
        assume k in dom z0; then
A17:    k in Seg n & k in dom z by RELAT_1:57; then
        consider sk be Function of A,REAL such that
A18:      sk = s.k & z.k = sk.t by A14;
        take sk;
        thus thesis by A17,A18,FUNCT_1:49;
      end;
      dom z = Seg(n+1) by A11,A12,FINSEQ_1:def 3; then
      consider sk be Function of A,REAL such that
A19:    sk = s.(n+1) & z.(n+1) = sk.t by A14,FINSEQ_1:4;
A20:  1 <= n+1 <= len z by A11,A12,NAT_1:11;
      z = (z|n)^<*z/.(n+1)*> by A11,A12,FINSEQ_5:21; then
B21:  z = (z|n)^<*z.(n+1)*> by A20,FINSEQ_4:15;
      Sum s0 is
        Point of R_Normed_Algebra_of_BoundedFunctions(A) by Lm1; then
      reconsider g1=Sum s0 as Function of A,REAL by LM88;
      dom s = Seg(n+1) by A11,FINSEQ_1:def 3; then
      s.(n+1) in rng s by FUNCT_1:3,FINSEQ_1:4; then
      reconsider v=s.(n+1) as Point of V;
      v is Point of R_Normed_Algebra_of_BoundedFunctions(A) by Lm1; then
      reconsider v1=v as Function of A,REAL by LM88;
A23:  n = len s0 & n = len z0 by A11,A12,FINSEQ_1:59,NAT_1:11; then
      s0 = s | dom s0 by FINSEQ_1:def 3; then
A24:  Sum s = Sum s0 + v by A11,A23,RLVECT_1:38;
      Sum s is Point of R_Normed_Algebra_of_BoundedFunctions(A) by Lm1; then
      reconsider g0=Sum s as Function of A,REAL by LM88;
A25:  g0.t = g1.t + sk.t by A19,A15,A24,C0SP1:29;
      g1.t = Sum z0 by A10,A16,A23;
      hence g.t = Sum z by A13,A25,B21,A19,RVSUM_1:74;
  end;
  for n be Nat holds P[n] from NAT_1:sch 2(A2,A9);
  hence thesis by A1;
end;
