reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (sin (#) tan) implies (sin (#)tan) is_differentiable_on Z &
  for x st x in Z holds((sin (#) tan)`|Z).x = sin.x + sin.x/(cos.x)^2
proof
A1: for x st x in Z holds sin is_differentiable_in x by SIN_COS:64;
  assume
A2: Z c= dom (sin (#) tan);
  then
A3: Z c= dom sin /\ dom tan by VALUED_1:def 4;
  then
A4: Z c= dom tan by XBOOLE_1:18;
  for x st x in Z holds tan is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.x <> 0 by A4,FDIFF_8:1;
    hence thesis by FDIFF_7:46;
  end;
  then
A5: tan is_differentiable_on Z by A4,FDIFF_1:9;
  Z c= dom sin by A3,XBOOLE_1:18;
  then
A6: sin is_differentiable_on Z by A1,FDIFF_1:9;
A7: for x st x in Z holds diff(tan, x)=1/(cos.x)^2
  proof
    let x;
    assume x in Z;
    then cos.x<>0 by A4,FDIFF_8:1;
    hence thesis by FDIFF_7:46;
  end;
  for x st x in Z holds((sin (#) tan)`|Z).x = sin.x + sin.x/(cos.x)^2
  proof
    let x;
    assume
A8: x in Z;
    then ((sin (#) tan)`|Z).x = diff(sin,x)*tan.x+sin.x*diff(tan,x) by A2,A5,A6
,FDIFF_1:21
      .=cos.x*tan.x+sin.x*diff(tan,x) by SIN_COS:64
      .=cos.x*tan.x+sin.x*(1/(cos.x)^2) by A7,A8
      .=(sin.x/cos.x)*(cos.x/1)+sin.x/(cos.x)^2 by A4,A8,RFUNCT_1:def 1
      .=sin.x*(cos.x/cos.x) + sin.x/(cos.x)^2
      .=sin.x* 1 + sin.x/(cos.x)^2 by A4,A8,FDIFF_8:1,XCMPLX_1:60
      .= sin.x +sin.x/(cos.x)^2;
    hence thesis;
  end;
  hence thesis by A2,A5,A6,FDIFF_1:21;
end;
