reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (tan*exp_R) implies tan*exp_R is_differentiable_on Z & for x
  st x in Z holds ((tan*exp_R)`|Z).x = exp_R.x/(cos.(exp_R.x))^2
proof
  assume
A1: Z c= dom (tan*exp_R);
A2: for x st x in Z holds cos.(exp_R.x)<>0
  proof
    let x;
    assume x in Z;
    then exp_R.x in dom (sin/cos) by A1,FUNCT_1:11;
    hence thesis by Th1;
  end;
A3: for x st x in Z holds tan*exp_R is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.(exp_R.x)<>0 by A2;
    then exp_R is_differentiable_in x & tan is_differentiable_in exp_R.x by
FDIFF_7:46,SIN_COS:65;
    hence thesis by FDIFF_2:13;
  end;
  then
A4: tan*exp_R is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((tan*exp_R)`|Z).x = exp_R.x/(cos.(exp_R.x))^2
  proof
    let x;
    assume
A5: x in Z;
    then
A6: cos.(exp_R.x)<>0 by A2;
    then exp_R is_differentiable_in x & tan is_differentiable_in exp_R.x by
FDIFF_7:46,SIN_COS:65;
    then diff(tan*exp_R,x) = diff(tan, exp_R.x)*diff(exp_R,x) by FDIFF_2:13
      .=(1/(cos.(exp_R.x))^2) * diff(exp_R,x) by A6,FDIFF_7:46
      .=exp_R.x/(cos.(exp_R.x))^2 by SIN_COS:65;
    hence thesis by A4,A5,FDIFF_1:def 7;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
