reserve FT for non empty RelStr,
  A,B,C for Subset of FT;

theorem
  for A being Subset of FT holds A is open iff (for z being Element of
FT st U_FT z c= A holds z in A)& for x being Element of FT st x in A holds U_FT
  x c= A
proof
  let A be Subset of FT;
  hereby
    assume A is open;
    then
A1: A = A^i;
    hence for z being Element of FT st U_FT z c= A holds z in A;
    for x being Element of FT st x in A holds U_FT x c= A
    proof
      let x be Element of FT;
      assume x in A;
      then ex y being Element of FT st x=y & U_FT y c= A by A1;
      hence thesis;
    end;
    hence for x being Element of FT st x in A holds U_FT x c= A;
  end;
  assume that
A2: for z being Element of FT st U_FT z c= A holds z in A and
A3: for x being Element of FT st x in A holds U_FT x c= A;
A4: A c= { y where y is Element of FT: U_FT y c= A}
  proof
    let u be object;
    assume
A5: u in A;
    then reconsider y2=u as Element of FT;
    U_FT y2 c= A by A3,A5;
    hence thesis;
  end;
  { y where y is Element of FT: U_FT y c= A} c= A
  proof
    let u be object;
    assume u in { y where y is Element of FT: U_FT y c= A};
    then ex y being Element of FT st y=u & U_FT y c= A;
    hence thesis by A2;
  end;
  then A = A^i by A4;
  hence thesis;
end;
