
theorem
  for T1,T2 being non empty TopSpace, f being Function of T1,T2 st T1 is
  sequential holds f is continuous iff for S1 being sequence of T1, S2 being
  sequence of T2 st S2=f*S1 holds f.:(Lim S1) c= Lim S2
proof
  let T1,T2 be non empty TopSpace, f be Function of T1,T2;
  assume
A1: T1 is sequential;
  thus f is continuous implies for S1 being sequence of T1, S2 being sequence
  of T2 st S2=f*S1 holds f.:(Lim S1) c= Lim S2 by Th11;
  assume
A2: for S1 being sequence of T1, S2 being sequence of T2 st S2=f*S1
  holds f.:(Lim S1) c= Lim S2;
  let B be Subset of T2;
  reconsider A=f"B as Subset of T1;
  assume
A3: B is closed;
  for S being sequence of T1 st S is convergent & rng S c= A holds Lim S c= A
  proof
    reconsider B9=B as Subset of T2;
    let S be sequence of T1;
    assume that
    S is convergent and
A4: rng S c= A;
    set S2=f*S;
    rng S2 c= B9
    proof
      let z be object;
      assume z in rng S2;
      then consider n being object such that
A5:   n in dom S2 and
A6:   z = S2.n by FUNCT_1:def 3;
      dom S = NAT by NORMSP_1:12;
      then S.n in rng S by A5,FUNCT_1:def 3;
      then f.(S.n) in B by A4,FUNCT_1:def 7;
      hence thesis by A5,A6,FUNCT_1:12;
    end;
    then
A7: Lim S2 c= B9 by A3,Th9;
    let x be object;
A8: dom f = the carrier of T1 by FUNCT_2:def 1;
A9: f.:(Lim S) c= Lim S2 by A2;
    assume
A10: x in Lim S;
    then f.x in f.:(Lim S) by A8,FUNCT_1:def 6;
    then f.x in Lim S2 by A9;
    hence thesis by A10,A8,A7,FUNCT_1:def 7;
  end;
  hence thesis by A1;
end;
