reserve x,y for Real,
  i, j for non zero Element of NAT,
  I, O for non empty set,
  s,s1,s2,s3 for Element of I,
  w, w1, w2 for FinSequence of I,
  t for Element of O,
  S for non empty FSM over I,
  q, q1 for State of S;

theorem
  (for s1,s2,q holds (the Tran of S).[q,s1] = (the Tran of S).[ q,s2]) implies
  S is calculating_type
proof
  assume
A1: for s1,s2,q holds (the Tran of S).[q,s1] = (the Tran of S).[q,s2];
  for j holds for w1,w2 st w1.1 = w2.1 & j <= len(w1)+1 & j <= len(w2)+1 holds
  GEN(w1, the InitS of S).j = GEN(w2, the InitS of S).j
  proof
    let j;
    let w1,w2;
    assume that
A2: w1.1 = w2.1 and
A3: j <= len(w1)+1 and
A4: j <= len(w2)+1;
    defpred P[Nat] means for w1,w2 st w1.1 = w2.1 &
    $1 <= len(w1) + 1 & $1 <= len(w2) + 1
    holds GEN(w1, the InitS of S).$1 = GEN(w2, the InitS of S).$1;
A5: P[1]
    proof
      let w1,w2;
      GEN(w1, the InitS of S).1 = the InitS of S by FSM_1:def 2;
      hence thesis by FSM_1:def 2;
    end;
A6: for h being non zero Nat st P[h] holds P[h+1]
    proof
      let h be non zero Nat;
      assume
A7:   for w1,w2 st w1.1 = w2.1 & h <= len(w1)+1 & h <= len(w2)+1 holds
      GEN(w1, the InitS of S).h = GEN(w2, the InitS of S).h;
      let w1,w2;
      assume that
A8:   w1.1 = w2.1 and
A9:   h+1 <= len(w1)+1 and
A10:  h+1 <= len(w2)+1;
A11:  h <= len(w1) by A9,XREAL_1:6;
A12:  h <= len(w1)+1 by A9,NAT_1:13;
      1 <= h by NAT_1:14;
      then consider WI being Element of I, QI, QI1 being State of S such that
      WI = w1.h and
A13:  QI = GEN(w1, the InitS of S).h and
A14:  QI1 = GEN(w1, the InitS of S).(h+1) and
A15:  WI-succ_of QI = QI1 by A11,FSM_1:def 2;
A16:  h <= len(w2) by A10,XREAL_1:6;
A17:  h <= len(w2)+1 by A10,NAT_1:13;
      1 <= h by NAT_1:14;
      then consider WI2 being Element of I,
      QI2, QI12 being State of S such that
      WI2 = w2.h and
A18:  QI2 = GEN(w2, the InitS of S).h and
A19:  QI12 = GEN(w2, the InitS of S).(h+1) and
A20:  WI2-succ_of QI2 = QI12 by A16,FSM_1:def 2;
      QI = QI2 by A7,A8,A12,A13,A17,A18;
      hence thesis by A1,A14,A15,A19,A20;
    end;
    for j being non zero Nat holds P[j] from NAT_1:sch 10(A5,A6);
    hence thesis by A2,A3,A4;
  end;
  hence thesis;
end;
