reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th12:
  Int v_strip(G,0) = { |[r,s]| : r < G*(1,1)`1 }
proof
  0 <> width G by MATRIX_0:def 10;
  then 1 <= width G by NAT_1:14;
  then
A1: v_strip(G,0) = { |[r,s]| : r <= G*(1,1)`1 } by GOBOARD5:10;
  thus Int v_strip(G,0) c= { |[r,s]| : r < G*(1,1)`1 }
  proof
    let x be object;
    assume
A2: x in Int v_strip(G,0);
    then reconsider u = x as Point of Euclid 2 by Lm6;
    consider r1 being Real such that
A3: r1 > 0 and
A4: Ball(u,r1) c= v_strip(G,0) by A2,Th5;
    reconsider p = u as Point of TOP-REAL 2 by Lm6;
A5: p = |[p`1,p`2]| by EUCLID:53;
    set q = |[p`1+r1/2,p`2+0]|;
    r1/2 < r1 by A3,XREAL_1:216;
    then q in Ball(u,r1) by A3,A5,Th7;
    then q in v_strip(G,0) by A4;
    then ex r2,s2 st q = |[r2,s2]| & r2 <= G*(1,1)`1 by A1;
    then
A6: p`1+r1/2 <= G*(1,1)`1 by SPPOL_2:1;
    p`1 < p`1 + r1/2 by A3,XREAL_1:29,215;
    then p`1 < G*(1,1)`1 by A6,XXREAL_0:2;
    hence thesis by A5;
  end;
  let x be object;
  assume x in { |[r,s]| : r < G*(1,1)`1 };
  then consider r,s such that
A7: x = |[r,s]| and
A8: r < G*(1,1)`1;
  reconsider u = |[r,s]| as Point of Euclid 2 by TOPREAL3:8;
A9: Ball(u,G*(1,1)`1-r) c= v_strip(G,0)
  proof
    let y be object;
A10: Ball(u,G*(1,1)`1-r) = { v : dist(u,v)<G*(1,1)`1-r} by METRIC_1:17;
    assume y in Ball(u,G*(1,1)`1-r);
    then consider v such that
A11: v = y and
A12: dist(u,v)<G*(1,1)`1-r by A10;
    reconsider q = v as Point of TOP-REAL 2 by TOPREAL3:8;
    (r - q`1)^2 >= 0 & (r - q`1)^2 + 0 <= (r - q`1)^2 + (s - q`2)^2 by
XREAL_1:6,63;
    then
A13: sqrt (r - q`1)^2 <= sqrt ((r - q`1)^2 + (s - q`2)^2) by SQUARE_1:26;
A14: q = |[q`1,q`2]| by EUCLID:53;
    then sqrt ((r - q`1)^2 + (s - q`2)^2) < G*(1,1)`1-r by A12,Th6;
    then sqrt (r - q`1)^2 <= G*(1,1)`1-r by A13,XXREAL_0:2;
    then
A15: |.r-q`1.| <= G*(1,1)`1-r by COMPLEX1:72;
    per cases;
    suppose
      r <= q`1;
      then
A16:  q`1-r >= 0 by XREAL_1:48;
      |.r-q`1.| = |.-(r-q`1).| by COMPLEX1:52
        .= q`1 - r by A16,ABSVALUE:def 1;
      then q`1 <= G*(1,1)`1 by A15,XREAL_1:9;
      hence thesis by A1,A11,A14;
    end;
    suppose
      r >= q`1;
      then q`1 <= G*(1,1)`1 by A8,XXREAL_0:2;
      hence thesis by A1,A11,A14;
    end;
  end;
  reconsider B = Ball(u,G*(1,1)`1-r) as Subset of TOP-REAL2 by TOPREAL3:8;
A17: B is open by Th3;
  u in Ball(u,G*(1,1)`1-r) by A8,Th1,XREAL_1:50;
  hence thesis by A7,A9,A17,TOPS_1:22;
end;
