reserve f for non constant standard special_circular_sequence,
  i,j,k,i1,i2,j1,j2 for Nat,
  r,s,r1,s1,r2,s2 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board;

theorem Th11:
  j <= width G implies Int h_strip(G,j) is convex
proof
  assume
A1: j <= width G;
  per cases by A1,NAT_1:14,XXREAL_0:1;
  suppose j = 0;
    then Int h_strip(G,j) = { |[r,s]| : s < G*(1,1)`2 } by GOBOARD6:15;
    hence thesis by JORDAN1:17;
  end;
  suppose j = width G;
    then Int h_strip(G,j) = { |[r,s]| : G*(1,width G)`2 < s } by GOBOARD6:16;
    hence thesis by JORDAN1:15;
  end;
  suppose 1 <= j & j < width G;
    then
A2: Int h_strip(G,j) = { |[r,s]| : G*(1,j)`2 < s & s < G*(1,j+1)`2 }
    by GOBOARD6:17;
A3: { |[r,s]| : G*(1,j)`2 < s} c= the carrier of TOP-REAL 2
    proof
      let x be object;
      assume x in { |[r,s]| : G*(1,j)`2 < s};
      then ex r,s st x = |[r,s]| & G*(1,j)`2 < s;
      hence thesis;
    end;
    { |[r,s]| : s < G*(1,j+1)`2 } c= the carrier of TOP-REAL 2
    proof
      let x be object;
      assume x in { |[r,s]| : s < G*(1,j+1)`2 };
      then ex r,s st x = |[r,s]| & s < G*(1,j+1)`2;
      hence thesis;
    end;
    then reconsider P = { |[r,s]| : G*(1,j)`2 < s},
    Q = { |[r,s]| : s < G*(1,j+1)`2 } as Subset of TOP-REAL 2 by A3;
A4: Int h_strip(G,j) = P /\ Q
    proof
      hereby
        let x be object;
        assume x in Int h_strip(G,j);
        then
A5:     ex r,s st x = |[r,s]| & G*(1,j)`2 < s & s < G*(1,j+1)`2 by A2;
        then
A6:     x in P;
        x in Q by A5;
        hence x in P /\ Q by A6,XBOOLE_0:def 4;
      end;
      let x be object;
      assume
A7:   x in P /\ Q;
      then x in P by XBOOLE_0:def 4;
      then consider r1,s1 such that
A8:   x = |[r1,s1]| and
A9:   G*(1,j)`2 < s1;
      x in Q by A7,XBOOLE_0:def 4;
      then consider r2,s2 such that
A10:  x = |[r2,s2]| and
A11:  s2 < G*(1,j+1)`2;
      s1 = s2 by A8,A10,SPPOL_2:1;
      hence thesis by A2,A8,A9,A11;
    end;
A12: P is convex by JORDAN1:15;
    Q is convex by JORDAN1:17;
    hence thesis by A4,A12,Th5;
  end;
end;
