reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;

theorem Th12:
  for P being Subset of (TOP-REAL 2)|(L~f)` st P is a_component
  holds P = RightComp f or P = LeftComp f
proof
  let P be Subset of (TOP-REAL 2)|(L~f)`;
  assume that
A1: P is a_component and
A2: P <> RightComp f;
  P <> {}((TOP-REAL 2)|(L~f)`) by A1,CONNSP_1:32;
  then consider a being Point of (TOP-REAL 2)|(L~f)` such that
A3: a in P by SUBSET_1:4;
  the carrier of (TOP-REAL 2)|(L~f)` = (L~f)` & (L~f)` = LeftComp f \/
  RightComp f by GOBRD12:10,PRE_TOPC:8;
  then
A4: a in LeftComp f or a in RightComp f by XBOOLE_0:def 3;
  LeftComp f is_a_component_of (L~f)` by GOBOARD9:def 1;
  then
A5: ex L being Subset of (TOP-REAL 2)|(L~f)` st L = LeftComp f & L
  is a_component by CONNSP_1:def 6;
  RightComp f is_a_component_of (L~f)` by GOBOARD9:def 2;
  then consider R being Subset of (TOP-REAL 2)|(L~f)` such that
A6: R = RightComp f and
A7: R is a_component by CONNSP_1:def 6;
  P misses R by A1,A2,A6,A7,CONNSP_1:35;
  then P meets LeftComp f by A6,A3,A4,XBOOLE_0:3;
  hence thesis by A1,A5,CONNSP_1:35;
end;
