reserve p, q for FinSequence,
  e,X for set,
  i, j, k, m, n for Nat,
  G for Graph;
reserve x,y,v,v1,v2,v3,v4 for Element of G;
reserve vs, vs1, vs2 for FinSequence of the carrier of G,
  c, c1, c2 for oriented Chain of G;

theorem Th12:
  1<=m & m<=n & n<=len c & q = (m,n)-cut c implies q is oriented Chain of G
proof
  assume that
A1: 1<=m and
A2: m<=n and
A3: n<=len c and
A4: q = (m,n)-cut c;
  consider vs such that
A5: vs is_oriented_vertex_seq_of c by Th9;
A6: len q +m-m=n+1-m by A1,A2,A3,A4,FINSEQ_6:def 4;
  reconsider qq=q as Chain of G by A1,A2,A3,A4,GRAPH_2:41;
  for n st 1 <= n & n < len q holds
  (the Source of G).(q.(n+1)) = (the Target of G).(q.n)
  proof
    let k be Nat;
    assume that
A7: 1<=k and
A8: k<len q;
    1-1<=m-1 by A1,XREAL_1:9;
    then m-1 = m-'1 by XREAL_0:def 2;
    then reconsider m1= m-1 as Element of NAT;
    reconsider i = m1+k as Nat;
    set v1 = vs/.i;
    set v2 = vs/.(i+1);
    0+1<=k by A7;
    then consider j such that
    0<=j and
A9: j<len q and
A10: k=j+1 by A8,FINSEQ_6:127;
A11: i= m+j by A10;
    i+1= m+(j+1) by A10;
    then
A12: c.(i+1)=q.(k+1) by A1,A2,A3,A4,A8,FINSEQ_6:def 4;
A13: c.i=q.k by A1,A2,A3,A4,A9,A10,A11,FINSEQ_6:def 4;
    1-1<=m-1 by A1,XREAL_1:9;
    then
A14: 0+1<=m-1+k by A7,XREAL_1:7;
    i<=(m-1)+(n-(m-1)) by A6,A8,XREAL_1:6;
    then i<=len c by A3,XXREAL_0:2;
    then c.i orientedly_joins v1, v2 by A5,A14;
    then
A15: (the Target of G).(c.i) = v2;
A16: 1<i+1 by A14,NAT_1:13;
    k+m<n+1 by A6,A8,XREAL_1:6;
    then k+m<=n by NAT_1:13;
    then m+k<=len c by A3,XXREAL_0:2;
    then c.(i+1) orientedly_joins v2, vs/.(i+1+1) by A5,A16;
    hence thesis by A12,A13,A15;
  end;
  then qq is oriented by GRAPH_1:def 15;
  hence thesis;
end;
