reserve i,j,n,n1,n2,m,k,l,u for Nat,
        r,r1,r2 for Real,
        x,y for Integer,
        a,b for non trivial Nat,
        F for XFinSequence,
        cF,cF1,cF2 for complex-valued XFinSequence,
        c,c1,c2 for Complex;

theorem
  for X1,X2 being natural-valued XFinSequence st len X1=len X2 &
    for n st n in dom X1 holds X1.n <= X2.n holds
      Product X1 <= Product X2
proof
  defpred P[Nat] means
  for X1,X2 be natural-valued XFinSequence st len X1=$1 =len X2 &
  for n st n in dom X1 holds X1.n <= X2.n holds
  Product X1 <= Product X2;
A1:  P[0]
  proof let X1,X2 be natural-valued XFinSequence;assume len X1=0 =len X2;
    then X1={}=X2;
    hence thesis;
  end;
A2: P[n] implies P[n+1]
  proof set n1=n+1;
    assume
A3:   P[n];
    let X1,X2 be natural-valued XFinSequence;
    assume that
A4:   len X1=n1=len X2 and
A5:   for i st i in dom X1 holds X1.i <= X2.i;
    X1=(X1|n) ^ <%X1.n%> by A4,AFINSQ_1:56;
    then
A6:   Product X1 = Product (X1|n) * Product <%X1.n%> by Th7
        .= Product (X1|n) * X1.n by Th5;
    X2=(X2|n) ^ <%X2.n%> by A4,AFINSQ_1:56;
    then
A7:   Product X2 = Product (X2|n) * Product <%X2.n%> by Th7
        .= Product (X2|n) * X2.n by Th5;
A8: n < n1 by NAT_1:13;
    then
A9:   n in dom X1 & len (X1|n) = n = len (X2|n) by A4,AFINSQ_1:54,66;
A10:  X1.n <= X2.n by A5,A8,A4,AFINSQ_1:66;
    for i st i in dom (X1|n) holds (X1|n).i <= (X2|n).i
    proof
      let i;
      assume i in dom (X1|n);
      then (X1|n).i =X1.i & (X2|n).i =X2.i & i in dom X1
        by A8,A4,A9,AFINSQ_1:53;
      hence thesis by A5;
    end;
    then Product (X1|n) <= Product (X2|n) by A3,A9;
    hence thesis by A6,A7,A10,XREAL_1:66;
  end;
  P[n] from NAT_1:sch 2(A1,A2);
  hence thesis;
end;
