reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;

theorem Th12:
  a*(n+1) <> 0 implies (1/(a*(n+1)))(#)( #Z (n+1)*AffineMap(a,b))
is_differentiable_on REAL & for x holds (((1/(a*(n+1)))(#)( #Z (n+1)*AffineMap(
  a,b)))`|REAL).x = (a*x+b) #Z n
proof
  assume
A1: a*(n+1) <> 0;
A2: [#]REAL = dom((1/(a*(n+1)))(#)( #Z (n+1)*AffineMap(a,b))) by FUNCT_2:def 1;
A3: [#]REAL = dom (AffineMap(a,b)) by FUNCT_2:def 1;
A4: for x st x in REAL holds AffineMap(a,b).x=a*x + b by FCONT_1:def 4;
  then
A5: AffineMap(a,b) is_differentiable_on REAL by A3,FDIFF_1:23;
  #Z (n+1)*AffineMap(a,b) is_differentiable_in x
  proof
    x in REAL by XREAL_0:def 1;
    then AffineMap(a,b) is_differentiable_in x by A3,A5,FDIFF_1:9;
    hence thesis by TAYLOR_1:3;
  end;
  then
  [#]REAL = dom ( #Z (n+1)*AffineMap(a,b)) & for x st x in REAL holds #Z (
  n+1) *AffineMap(a,b) is_differentiable_in x by FUNCT_2:def 1;
  then
A6: #Z (n+1)*AffineMap(a,b) is_differentiable_on REAL by FDIFF_1:9;
 hence (1/(a*(n+1)))(#)( #Z (n+1)*AffineMap(a,b))
is_differentiable_on REAL by A2,FDIFF_1:20;
A7: for x st x in REAL holds (( #Z (n+1)*AffineMap(a,b))`|REAL).x=a*(n+1)*(
  AffineMap(a,b).x) #Z n
  proof
    set m=n+1;
    let x;
    assume
A8: x in REAL;
    AffineMap(a,b) is_differentiable_in x by A3,A5,FDIFF_1:9,A8;
    then diff(( #Z m*AffineMap(a,b)),x) = m * (AffineMap(a,b).x) #Z (m-1) *
    diff(AffineMap(a,b),x) by TAYLOR_1:3
      .= m * (AffineMap(a,b).x) #Z (m-1) * ((AffineMap(a,b))`|REAL).x by A5,
FDIFF_1:def 7,A8
      .= m * (AffineMap(a,b).x) #Z (m-1) *a by A3,A4,FDIFF_1:23,A8;
    hence thesis by A6,FDIFF_1:def 7,A8;
  end;
A9:
  for x st x in REAL holds (((1/(a*(n+1)))(#)( #Z (n+1)*AffineMap(a,b)))
  `|REAL).x =(a*x+b) #Z n
  proof
    let x;
    assume
A10: x in REAL;
    (((1/(a*(n+1)))(#)( #Z (n+1)*AffineMap(a,b)))`|REAL).x =(1/(a*(n+1)))
    *diff( #Z (n+1)*AffineMap(a,b),x) by A2,A6,FDIFF_1:20,A10
      .=(1/(a*(n+1)))*((( #Z (n+1)*AffineMap(a,b))`|REAL).x) by A6,
FDIFF_1:def 7,A10
      .=(1/(a*(n+1)))*(a*(n+1) * (AffineMap(a,b).x) #Z n ) by A7,A10
      .=(1/(a*(n+1)))*(a*(n+1)) * (AffineMap(a,b).x) #Z n
      .=(a*(n+1))/(a*(n+1)) * (AffineMap(a,b).x) #Z n by XCMPLX_1:99
      .=1*(AffineMap(a,b).x) #Z n by A1,XCMPLX_1:60
      .=(a*x+b) #Z n by FCONT_1:def 4;
    hence thesis;
  end;
  let x;
   x in REAL by XREAL_0:def 1;
  hence thesis by A9;
end;
