reserve A for non empty closed_interval Subset of REAL;
reserve rho for Function of A,REAL;
reserve u for PartFunc of REAL,REAL;
reserve T for DivSequence of A;
reserve S for middle_volume_Sequence of rho,u,T;
reserve k for Nat;

theorem Th4A:
  for A be non empty closed_interval Subset of REAL,
      r be Real, rho,rho1 be Function of A,REAL,
      u be PartFunc of REAL,REAL st
      rho is bounded_variation & rho1 is bounded_variation & dom u = A &
      rho = r(#)rho1 & u is_RiemannStieltjes_integrable_with rho1 holds
        u is_RiemannStieltjes_integrable_with rho &
        integral(u,rho) = r * integral(u,rho1)
proof
  let A be non empty closed_interval Subset of REAL,
      r be Real, rho,rho1 be Function of A,REAL,
      u be PartFunc of REAL,REAL;
  assume
A1: rho is bounded_variation & rho1 is bounded_variation & dom u = A &
    rho = r(#)rho1 & u is_RiemannStieltjes_integrable_with rho1;
A3: now let T be DivSequence of A, S be middle_volume_Sequence of rho,u,T;
    assume A4: delta(T) is convergent & lim delta(T) = 0;
    defpred P[Element of NAT, set] means ex p being FinSequence of REAL st
      p = $2 & len p = len (T.$1) & for i be Nat st i in dom (T.$1) holds
      (p.i) in dom (u|divset((T.$1),i)) & ex z be Real st
      z = (u|divset((T.$1),i)).(p.i) &
      (S.$1).i = z * (vol( divset((T.$1),i),rho));
A5: for k being Element of NAT ex p being Element of (REAL)* st P[k, p]
    proof
      let k be Element of NAT;
      defpred P1[ Nat, set] means $2 in dom (u|divset((T.k),$1)) &
        ex c be Real st c = (u|divset((T.k),$1)).($2) &
        (S.k).$1 = c * (vol( divset((T.k),$1),rho));
A6:   Seg len ((T.k)) = dom (T.k) by FINSEQ_1:def 3;
A7:   for i being Nat st i in Seg len (T.k) holds
        ex x being Element of REAL st P1[i,x]
      proof
        let i be Nat;
        assume i in Seg len (T.k); then
        i in dom (T.k) by FINSEQ_1:def 3; then
        consider c be Real such that
A8:       c in rng (u|divset((T.k),i)) &
          (S.k).i = c * (vol( divset((T.k),i),rho)) by Def1,A1;
        consider x be object such that
A9:       x in dom (u|divset((T.k),i)) &
          c = (u|divset((T.k),i)).x by A8,FUNCT_1:def 3;
        reconsider x as Element of REAL by A9;
        take x;
        thus thesis by A8,A9;
      end;
      consider p being FinSequence of REAL such that
A10:    dom p = Seg len (T.k) & for i being Nat st i in Seg len (T.k) holds
        P1[i,p.i] from FINSEQ_1:sch 5(A7);
      take p;
      len p = len (T.k) by A10,FINSEQ_1:def 3;
      hence thesis by A10,A6,FINSEQ_1:def 11;
    end;
    consider F being sequence of (REAL)* such that
A11:  for x being Element of NAT holds P[x, F.x] from FUNCT_2:sch 3(A5);
    defpred P1[Element of NAT,set] means ex q be middle_volume of rho1,u,T.$1
      st q = $2 & for i be Nat st i in dom (T.$1) holds ex z be Real st
      (F.$1).i in dom (u|divset((T.$1),i)) &
      z = (u|divset((T.$1),i)).((F.$1).i) &
      q.i = z * (vol (divset((T.$1),i),rho1));
A12: for k being Element of NAT
      ex y being Element of (REAL)* st P1[k, y]
    proof
      let k be Element of NAT;
      defpred P11[ Nat, set] means ex c be Real st
        (F.k).$1 in dom (u|divset((T.k),$1)) &
        c = (u|divset((T.k),$1)).((F.k).$1) &
        $2 = c *(vol(divset((T.k),$1),rho1));
A13:  Seg len (T.k) = dom (T.k) by FINSEQ_1:def 3;
A14:  for i being Nat st i in Seg len (T.k) holds ex
        x being Element of REAL st P11[i,x]
      proof
        let i be Nat;
        assume i in Seg len (T.k); then
A15:    i in dom (T.k) by FINSEQ_1:def 3;
        consider p being FinSequence of REAL such that
A16:      p = F.k & len p = len (T.k) & for i be Nat st i in dom (T.k) holds
          p.i in dom (u|divset((T.k),i)) & ex z be Real st
          z = (u|divset((T.k),i)).(p.i) &
          (S.k).i = z * (vol(divset((T.k),i),rho)) by A11;
        p.i in dom (u|divset((T.k),i)) by A15,A16; then
        (u|divset((T.k),i)).(p.i) in rng (u|divset((T.k),i))
          by FUNCT_1:3; then
        reconsider x = (u|divset((T.k),i)).(p.i) as Element of REAL;
        x * (vol(divset((T.k),i),rho1)) is Element of REAL by XREAL_0:def 1;
        hence thesis by A16,A15;
      end;
      consider q being FinSequence of REAL such that
A19:    dom q = Seg len (T.k) & for i being Nat st i in Seg len (T.k) holds
        P11[i,q.i] from FINSEQ_1:sch 5(A14);
A20:  len q = len (T.k) by A19,FINSEQ_1:def 3;
      now let i be Nat;
        assume i in dom (T.k); then
        i in Seg len (T.k) by FINSEQ_1:def 3; then
        consider c be Real such that
A21:      (F.k).i in dom (u|divset((T.k),i)) &
          c = (u|divset((T.k),i)).((F.k).i) &
          q.i = c * (vol(divset((T.k),i),rho1)) by A19;
        thus ex c be Real st c in rng (u|divset((T.k),i)) &
          q.i = c * (vol(divset((T.k),i),rho1)) by A21,FUNCT_1:3;
      end;
      then reconsider q as middle_volume of rho1,u,T.k by A20,Def1,A1;
      q is Element of (REAL)* by FINSEQ_1:def 11;
      hence thesis by A13,A19;
    end;
    consider Sf being sequence of (REAL)* such that
A22:  for x being Element of NAT holds P1[x, Sf.x] from FUNCT_2:sch 3(A12);
    now let k be Element of NAT;
      ex q be middle_volume of rho1,u,T.k st q = Sf.k &
        for i be Nat st i in dom (T.k) holds ex z be Real st
        (F.k).i in dom (u|divset((T.k),i)) &
        z = (u|divset((T.k),i)).((F.k).i) &
        q.i = z * (vol(divset((T.k),i),rho1)) by A22;
      hence Sf.k is middle_volume of rho1,u,T.k;
    end;
    then reconsider Sf as middle_volume_Sequence of rho1,u,T by Def3;
A23: middle_sum(Sf) is convergent &
      lim (middle_sum(Sf)) = integral(u,rho1) by A1,A4,Def6;
A24: r (#) middle_sum(Sf) = middle_sum(S)
    proof
      now let n be Nat;
A25:    n in NAT by ORDINAL1:def 12;
        consider p being FinSequence of REAL such that
A26:      p = F.n & len p = len (T.n) & for i be Nat st i in dom (T.n) holds
          (p.i) in dom (u|divset((T.n),i)) & ex z be Real st
          z = (u|divset((T.n),i)).(p.i) &
          (S.n).i = z * (vol(divset((T.n),i),rho)) by A11,A25;
        consider q be middle_volume of rho1,u,T.n such that
A27:      q = Sf.n & for i be Nat st i in dom (T.n) holds ex z be Real st
          (F.n).i in dom (u|divset((T.n),i)) &
          z = (u|divset((T.n),i)).((F.n).i) &
          q.i = z * (vol(divset((T.n),i),rho1)) by A22,A25;
B28:    len (Sf.n) = len (T.n) & len (S.n) = len (T.n) by A1,Def1; then
A28:    dom (Sf.n) = dom (T.n) & dom (S.n) = dom (T.n) by FINSEQ_3:29;
        now let x be object;
         assume A29: x in dom(S.n); then
         reconsider i = x as Nat;
         consider t be Real such that
A30:       t = (u|divset((T.n),i)).((F.n).i) &
           (S.n).i = t * (vol(divset((T.n),i),rho)) by A29,A28,A26;
         consider z be Real such that
A31:       (F.n).i in dom (u|divset((T.n),i)) &
           z = (u|divset((T.n),i)).((F.n).i) &
           q.i = z * (vol(divset((T.n),i),rho1)) by A27,A29,A28;
         i in dom(T.n) by A29,FINSEQ_3:29,B28; then
         vol(divset((T.n),i),rho) = r * vol(divset((T.n),i),rho1)
           by A1,Lm4A,INTEGRA1:8;
         hence (S.n).x = r * ((Sf.n).x) by A31,A27,A30;
        end; then
A38:    r(#)(Sf.n) = S.n by A28,VALUED_1:def 5;
        thus r * (middle_sum(Sf)).n
                    = r * (Sum(Sf.n)) by Def4
                   .= Sum(S.n) by A38,RVSUM_1:87
                   .= (middle_sum(S)).n by Def4;
      end;
      hence thesis by SEQ_1:9;
    end;
    thus middle_sum(S) is convergent by A23,A24;
    thus lim (middle_sum(S)) = r * integral(u,rho1) by A24,A23,SEQ_2:8;
  end;
  hence u is_RiemannStieltjes_integrable_with rho;
  hence integral(u,rho) = r * integral(u,rho1) by Def6,A3,A1;
end;
