reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem
  for r, t being Real holds r > 0 & t > 0 implies ex n being
  Nat st i < n & dist(Gauge(C,n)*(1,1),Gauge(C,n)*(1,2)) < r & dist(
  Gauge(C,n)*(1,1),Gauge(C,n)*(2,1)) < t
proof
  let r, t be Real;
  assume that
A1: r > 0 and
A2: t > 0;
  consider n being Nat such that
  1 < n and
A3: dist(Gauge(C,n)*(1,1),Gauge(C,n)*(1,2)) < r and
A4: dist(Gauge(C,n)*(1,1),Gauge(C,n)*(2,1)) < t by A1,A2,GOBRD14:11;
  per cases;
  suppose
A5: i < n;
    take n;
    thus thesis by A3,A4,A5;
  end;
  suppose
A6: i >= n;
    take i+1;
A7: i > n or i = n by A6,XXREAL_0:1;
    then
A8: dist(Gauge(C,i)*(1,1),Gauge(C,i)*(2,1)) <= dist(Gauge(C,n)*(1,1),
    Gauge(C,n)*(2,1)) by Th11;
A9: dist(Gauge(C,i)*(1,1),Gauge(C,i)*(1,2)) <= dist(Gauge(C,n)*(1,1),
    Gauge(C,n)*(1,2)) by A7,Th9;
    thus
A10: i < i+1 by NAT_1:13;
    then dist(Gauge(C,i+1)*(1,1),Gauge(C,i+1)*(1,2)) < dist(Gauge(C,i)*(1,1),
    Gauge(C,i)*(1,2)) by Th9;
    then
A11: dist(Gauge(C,i+1)*(1,1),Gauge(C,i+1)*(1,2)) < dist(Gauge(C,n)*(1,1),
    Gauge(C,n)*(1,2)) by A9,XXREAL_0:2;
    dist(Gauge(C,i+1)*(1,1),Gauge(C,i+1)*(2,1)) < dist(Gauge(C,i)*(1,1),
    Gauge(C,i)*(2,1)) by A10,Th11;
    then dist(Gauge(C,i+1)*(1,1),Gauge(C,i+1)*(2,1)) < dist(Gauge(C,n)*(1,1),
    Gauge(C,n)*(2,1)) by A8,XXREAL_0:2;
    hence thesis by A3,A4,A11,XXREAL_0:2;
  end;
end;
