reserve p,p1,p2,p3,q for Point of TOP-REAL 2;

theorem Th12:
  for P being compact non empty Subset of TOP-REAL 2, q1,q2 being
  Point of TOP-REAL 2 st P is being_simple_closed_curve & LE q1,q2,P & q1<>q2 &
  q1<>W-min(P) holds Segment(q2,W-min(P),P)/\ Segment(W-min(P),q1,P)={W-min(P)}
proof
  let P be compact non empty Subset of TOP-REAL 2, q1,q2 be Point of TOP-REAL
  2;
  assume that
A1: P is being_simple_closed_curve and
A2: LE q1,q2,P and
A3: q1<>q2 and
A4: q1<>W-min(P);
  thus Segment(q2,W-min(P),P)/\ Segment(W-min(P),q1,P) c= {W-min(P)}
  proof
    let x be object;
    assume
A5: x in Segment(q2,W-min(P),P)/\ Segment(W-min(P),q1,P);
    then x in Segment(q2,W-min(P),P) by XBOOLE_0:def 4;
    then x in {p1: LE q2,p1,P or q2 in P & p1=W-min(P)} by Def1;
    then consider p1 such that
A6: p1=x and
A7: LE q2,p1,P or q2 in P & p1=W-min(P);
A8: x in Segment(W-min(P),q1,P) by A5,XBOOLE_0:def 4;
    now
      per cases by A7;
      case
A9:     LE q2,p1,P;
        x in {p: LE W-min(P),p,P & LE p,q1,P} by A4,A8,Def1;
        then ex p2 st p2=x & LE W-min(P),p2,P & LE p2,q1,P;
        then LE q2,q1,P by A1,A6,A9,JORDAN6:58;
        hence contradiction by A1,A2,A3,JORDAN6:57;
      end;
      case
        q2 in P & p1=W-min(P);
        hence x=W-min(P) by A6;
      end;
    end;
    hence thesis by TARSKI:def 1;
  end;
  let x be object;
  assume x in {W-min(P)};
  then
A10: x=W-min(P) by TARSKI:def 1;
  q2 in P by A1,A2,Th5;
  then x in {p1: LE q2,p1,P or q2 in P & p1=W-min(P)} by A10;
  then
A11: x in Segment(q2,W-min(P),P) by Def1;
  q1 in P by A1,A2,Th5;
  then LE W-min(P),q1,P by A1,Th3;
  then x in Segment(W-min(P),q1,P) by A1,A10,Th6;
  hence thesis by A11,XBOOLE_0:def 4;
end;
