reserve x, y for object, X for set,
  i, j, k, l, n, m for Nat,
  D for non empty set,
  K for commutative Ring,
  a,b for Element of K,
  perm, p, q for Element of Permutations(n),
  Perm,P for Permutation of Seg n,
  F for Function of Seg n,Seg n,
  perm2, p2, q2, pq2 for Element of Permutations(n+2),
  Perm2 for Permutation of Seg (n+2);
reserve s for Element of 2Set Seg (n+2);

theorem Th12:
  for Id be Element of Permutations(n+2) st Id = idseq (n+2) holds
  sgn(Id,K) = 1_K
proof
  set n2=n+2;
  let Id be Element of Permutations n2 such that
A1: Id=idseq n2;
  set Path=Part_sgn(Id,K);
  set 2S=2Set Seg n2;
  2S in Fin 2S by FINSUB_1:def 5; then
  In (2S,Fin 2S)=2S by SUBSET_1:def 8;
  then reconsider 2S9=2S as Element of Fin 2S;
  now
    let x;
    assume x in 2S9;
    then consider i,j such that
A3: i in Seg n2 and
A4: j in Seg n2 and
A5: i < j and
A6: x={i,j} by Th1;
A7: Id.j=j by A1,A4,FUNCT_1:18;
    Id.i=i by A1,A3,FUNCT_1:18;
    hence Path.x=1_K by A3,A4,A5,A6,A7,Def1;
  end;
  hence thesis by Th4;
end;
