reserve X for non empty set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S,
  F,G for Functional_Sequence of X,ExtREAL,
  I for ExtREAL_sequence,
  f,g for PartFunc of X,ExtREAL,
  seq, seq1, seq2 for ExtREAL_sequence,
  p for ExtReal,
  n,m for Nat,
  x for Element of X,
  z,D for set;

theorem Th12:
  (for n be Nat holds G.n = (F.n)|D) & x in D implies (F#x is
  convergent_to_+infty implies G#x is convergent_to_+infty) & (F#x is
  convergent_to_-infty implies G#x is convergent_to_-infty) & (F#x is
convergent_to_finite_number implies G#x is convergent_to_finite_number) & (F#x
  is convergent implies G#x is convergent)
proof
  assume that
A1: for n be Nat holds G.n = (F.n)|D and
A2: x in D;
  thus
A3: F#x is convergent_to_+infty implies G#x is convergent_to_+infty
  proof
    assume
A4: F#x is convergent_to_+infty;
    let g be Real;
    assume 0 < g;
    then consider n be Nat such that
A5: for m be Nat st n <= m holds g <= (F#x).m by A4;
    take n;
    let m be Nat;
    assume n <= m;
    then g <= (F#x).m by A5;
    then g <= (F.m).x by MESFUNC5:def 13;
    then g <= ((F.m)|D).x by A2,FUNCT_1:49;
    then g <= (G.m).x by A1;
    hence g <= (G#x).m by MESFUNC5:def 13;
  end;
  thus
A6: F#x is convergent_to_-infty implies G#x is convergent_to_-infty
  proof
    assume
A7: F#x is convergent_to_-infty;
    let g be Real;
    assume g < 0;
    then consider n be Nat such that
A8: for m be Nat st n <= m holds (F#x).m <= g by A7;
    take n;
    let m be Nat;
    assume n <= m;
    then (F#x).m <= g by A8;
    then (F.m).x <= g by MESFUNC5:def 13;
    then ((F.m)|D).x <= g by A2,FUNCT_1:49;
    then (G.m).x <= g by A1;
    hence (G#x).m <= g by MESFUNC5:def 13;
  end;
  thus
A9: F#x is convergent_to_finite_number implies G#x is
  convergent_to_finite_number
  proof
    assume F#x is convergent_to_finite_number;
    then consider g be Real such that
A10: lim(F#x) = g and
A11: for p be Real st 0<p ex n be Nat st for m be Nat st n<=m
    holds |. (F#x).m - lim(F#x) .| < p by Th7;
    for p be Real st 0 < p ex n be Nat st for m be Nat st n <= m
    holds |. (G#x).m - (g) .| < p
    proof
      let p be Real;
      assume 0 < p;
      then consider n be Nat such that
A12:  for m be Nat st n <= m holds |. (F#x).m - lim(F#x) .| < p by A11;
      take n;
      let m be Nat;
      (F#x).m = (F.m).x by MESFUNC5:def 13;
      then (F#x).m = ((F.m)|D).x by A2,FUNCT_1:49;
      then
A13:  (F#x).m = (G.m).x by A1;
      assume n <= m;
      then |. (F#x).m - lim(F#x) .| < p by A12;
      hence thesis by A10,A13,MESFUNC5:def 13;
    end;
    hence thesis;
  end;
  assume
A14: F#x is convergent;
  per cases by A14;
  suppose
    F#x is convergent_to_+infty;
    hence thesis by A3;
  end;
  suppose
    F#x is convergent_to_-infty;
    hence thesis by A6;
  end;
  suppose
    F#x is convergent_to_finite_number;
    hence thesis by A9;
  end;
end;
