reserve T, T1, T2 for TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  A1 for Subset of T1,
  A2 for Subset of T2,
  TM, TM1, TM2 for metrizable TopSpace,
  Am, Bm for Subset of TM,
  Fm, Gm for Subset-Family of TM,
  C for Cardinal,
  iC for infinite Cardinal;

theorem Th12:
  T is T_1 & A is discrete implies A is open Subset of T|(Cl A)
proof
  assume that
A1: T is T_1 and
A2: A is discrete;
  set TA=T|(Cl A);
A3: [#]TA=Cl A by PRE_TOPC:def 5;
A4: A c=Cl A by PRE_TOPC:18;
  per cases;
  suppose
    TA is empty;
    hence thesis by A3,PRE_TOPC:18;
  end;
  suppose
    TA is non empty;
    then reconsider TA as non empty TopSpace;
    deffunc F(Element of TA)={$1};
    defpred P[set] means $1 in A;
    consider S be Subset-Family of TA such that
A5: S={F(x) where x is Element of TA:P[x]} from LMOD_7:sch 5;
A6: S is open
    proof
      let B be Subset of TA;
      assume B in S;
      then consider y be Element of TA such that
A7:   B=F(y) and
A8:   P[y] by A5;
      reconsider x=y as Point of T by A8;
      consider G be Subset of T such that
A9:   G is open and
A10:  A/\G={x} by A2,A8,TEX_2:26;
      reconsider X={x} as Subset of T by A10;
      T is non empty by A7;
      then
A11:  Cl X=X by A1,PRE_TOPC:22;
      x in {x} by TARSKI:def 1;
      then x in A & x in G by A10,XBOOLE_0:def 4;
      then
A12:  G/\Cl A<>{} by A4,XBOOLE_0:def 4;
      G/\Cl A c=Cl X by A9,A10,TOPS_1:13;
      then G/\Cl A=X by A11,A12,ZFMISC_1:33;
      hence thesis by A3,A7,A9,TSP_1:def 1;
    end;
    union S=A
    proof
      hereby
        let x be object;
        assume x in union S;
        then consider y be set such that
A13:    x in y and
A14:    y in S by TARSKI:def 4;
        ex z be Element of TA st F(z)=y & P[z] by A5,A14;
        hence x in A by A13,TARSKI:def 1;
      end;
      let x be object;
      assume x in A;
      then
A15:  {x} in S by A3,A4,A5;
      x in {x} by TARSKI:def 1;
      hence thesis by A15,TARSKI:def 4;
    end;
    hence thesis by A6,TOPS_2:19;
  end;
end;
