reserve E for RealLinearSpace;
reserve A, B, C for binary-image of E;
reserve a, b, v for Element of E;
reserve F, G for binary-image-family of E;
reserve A, B, C for non empty binary-image of E;

theorem Th12:
  (union F)(+)B = union {X(+)B where X is binary-image of E: X in F}
  proof
    for x be object
    holds x in (union F)(+)B
    iff x in union {X(+)B where X is binary-image of E: X in F}
    proof
      let x be object;
      hereby assume x in (union F)(+)B;
        then consider f, b be Element of E such that
        A1: x = f + b & f in (union F) & b in B;
        consider Y be set such that
        A2: f in Y & Y in F by A1,TARSKI:def 4;
        reconsider X = Y as binary-image of E by A2;
        A3: x in X(+)B by A1,A2;
        X(+)B in {W(+)B where W is binary-image of E: W in F } by A2;
        hence x in union {W(+)B where W is binary-image of E: W in F}
        by A3,TARSKI:def 4;
      end;

      assume x in union {X(+)B where X is binary-image of E: X in F};
      then consider Y be set such that
      A4: x in Y & Y in {X(+)B where X is binary-image of E: X in F}
      by TARSKI:def 4;
      consider W be binary-image of E such that
      A5: Y = W(+)B & W in F by A4;
      consider f, b be Element of E such that
      A6: x = f + b & f in W & b in B by A4,A5;
      W c= (union F) by A5,ZFMISC_1:74;
      hence x in (union F) (+)B by A6;
    end;
    hence thesis by TARSKI:2;
  end;
