
theorem Th12:
for m,n,b being Nat st b>1 holds m<n iff (len digits(m,b) < len digits(n,b)
or len digits(m,b) = len digits(n,b) & ex i being Nat st
i < len digits(m,b) & digits(m,b).i < digits(n,b).i &
for j being Nat st j<len digits(m,b) & digits(m,b).j<>digits(n,b).j holds i>=j)
proof
  let m,n,b be Nat;
  set dm=digits(m,b);
  set dn=digits(n,b);
  consider vm being XFinSequence of NAT such that
  A1: (dom vm = dom dm & for i being Nat st i in dom vm holds
  vm.i = (dm.i)*(b|^i)) & value(digits(m,b),b) = Sum vm by NUMERAL1:def 1;
  consider vn being XFinSequence of NAT such that
  A2: (dom vn = dom dn & for i being Nat st i in dom vn holds
  vn.i = (dn.i)*(b|^i)) & value(digits(n,b),b) = Sum vn by NUMERAL1:def 1;
  assume A3: b>1;
  thus m<n implies (len dm < len dn
  or len dm = len dn &
  ex i being Nat st i < len dm &
  dm.i < dn.i &
  for j being Nat st j < len dm & dm.j <> dn.j
  holds i>=j)
  proof
    assume A4: m<n;
    assume A5: len dm >= len dn;
    now
      assume A6: len dm > len dn;
      A7:
      now
        assume m = 0;
        then dm = <%0%> by NUMERAL1:def 2,A3;
        then len dm=1 by AFINSQ_1:def 4;
        hence contradiction by A3,A6,NUMERAL1:4;
      end;
      m >= b|^(len dn) & n < b|^(len dn) by A6,A3,A7,Th10,Th9;
      hence contradiction by A4,XXREAL_0:2;
    end;
    hence A8: len dm = len dn by A5,XXREAL_0:1;
    defpred P[Nat] means $1 < len dm & dm.$1 <> dn.$1;
    deffunc N()=len dm;
    A9: for k being Nat st P[k] holds k <= N();
    A10: ex k being Nat st P[k]
    proof
      assume A11: not thesis;
      now
        let a be object;
        assume a in dom dm;
        then A12: a in Segm dom dm;
        then reconsider k=a as Nat;
        k < len dm by A12,NAT_1:44;
        hence dm.a=dn.a by A11;
      end;
      then dm=dn by A8,FUNCT_1:2;
      then m=value(dn,b) by A3,NUMERAL1:5;
      then m=n by A3,NUMERAL1:5;
      hence contradiction by A4;
    end;
    consider i being Nat such that
    A13: P[i] & for n being Nat st P[n] holds n <= i from NAT_1:sch 6(A9,A10);
    take i;
    thus i < len dm by A13;

    thus dm.i < dn.i
    proof
      assume not thesis;
      then A14: dm.i > dn.i by A13,XXREAL_0:1;
      A15: i in Segm dom dm & i in Segm dom dn by A8,A13,NAT_1:44;

      per cases;
      suppose A16: i>0;
        A17:
        now
          assume n=0;
          then digits(n,b)=<%0%> by A3,NUMERAL1:def 2;
          then i < 1 & i >= 0+1 by A13,A8,A16,AFINSQ_1:34,NAT_1:14;
          hence contradiction;
        end;

        vm = (vm|i)^(vm/^i);
        then A18: Sum vm = Sum (vm|i) + Sum (vm/^i) by AFINSQ_2:55;

        vn = (vn|i)^(vn/^i);
        then A19: Sum vn = Sum (vn|i) + Sum (vn/^i) by AFINSQ_2:55;

        len dm >= 0+1 by A3,NUMERAL1:4;
        then reconsider ldm1=len dm - 1 as Nat by NAT_1:20;
        i < ldm1 + 1 by A13;
        then i <= ldm1 by NAT_1:13;
        then per cases by XXREAL_0:1;
        suppose A20: i=ldm1;
          then i < len dm by XREAL_1:44;
          then A21: len (vm/^i) = len vm - i by A1,AFINSQ_2:7 .= 1 by A20,A1;
          then 0 in Segm dom (vm/^i) by NAT_1:44;
          then (vm/^i).0 = vm.(0+i) by AFINSQ_2:def 2;
          then (vm/^i) = <%vm.i%> by A21,AFINSQ_1:34;
          then A22: Sum (vm/^i) = vm.i by AFINSQ_2:53;

          i < len dm by A20,XREAL_1:44;
          then A23: len (vn/^i) = len vn - i
          by A8,A2,AFINSQ_2:7 .= 1 by A8,A20,A2;
          then 0 in Segm dom (vn/^i) by NAT_1:44;
          then (vn/^i).0 = vn.(0+i) by AFINSQ_2:def 2;
          then (vn/^i) = <%vn.i%> by A23,AFINSQ_1:34;
          then A24: Sum (vn/^i) = vn.i by AFINSQ_2:53;

          A25: dom (dn|i) c= dom dn & dom (vn|i) c= dom vn by RELAT_1:60;

          consider d9 being XFinSequence of NAT such that
          A26: (dom d9 = dom (dn|i) &
          for a being Nat st a in dom d9 holds d9.a = ((dn|i).a)*(b|^a))
          & value(dn|i,b) = Sum d9 by NUMERAL1:def 1;

          A27: dom d9 = i by A26,A8,A13,AFINSQ_1:54
          .= dom (vn|i) by A2,A8,A13,AFINSQ_1:54;

          now
            let a be Nat;
            assume A28: a in dom d9;
            then d9.a = ((dn|i).a)*(b|^a) by A26;
            then A29: d9.a = (dn.a)*(b|^a) by A28,A26,FUNCT_1:47;
            A30: a in dom (vn|i) by A28,A27;
            then A31: (vn|i).a=vn.a by FUNCT_1:47;
            a in dom vn by A30,A25;
            then (vn|i).a=(dn.a)*(b|^a) by A31,A2;
            hence d9.a=(vn|i).a by A29;
          end;
          then d9=vn|i by A27,AFINSQ_1:8;
          then A32: value(dn|i,b)=Sum(vn|i) by A26;

          A33: len (dn|i) > 0 by A8,A13,A16,AFINSQ_1:54;
          for a being Nat st a in dom (dn|i) holds (dn|i).a<b
          proof
            let a be Nat;
            assume a in dom (dn|i);
            then a in dom dn & (dn|i).a = dn.a by A25,FUNCT_1:47;
            hence (dn|i).a<b by A17,NUMERAL1:def 2,A3;
          end;
          then value(dn|i,b) < b|^(len(dn|i)) by A33,Th8,A3;
          then value(dn|i,b) < b|^i by A8,A13,AFINSQ_1:54;

          then Sum (vn|i) < b|^i by A32;
          then Sum (vn|i)+vn.i < b|^i + vn.i by XREAL_1:6;
          then Sum (vn|i)+vn.i < b|^i + (dn.i)*(b|^i) by A2,A15;
          then A34: Sum (vn|i)+vn.i < (b|^i)*(1 + (dn.i));

          1 + (dn.i) <= dm.i by A14,NAT_1:13;
          then (b|^i)*(1 + (dn.i)) <= (b|^i)*(dm.i) by XREAL_1:64;
          then (b|^i)*(1 + (dn.i)) <= vm.i by A15,A1;
          then Sum (vn|i)+vn.i < vm.i by A34,XXREAL_0:2;
          then Sum (vn|i)+Sum (vn/^i) < Sum (vm/^i) by A22,A24;
          then Sum (vn|i)+Sum (vn/^i) < Sum (vm|i) + Sum (vm/^i) by XREAL_1:40;
          then Sum vn < Sum vm by A18,A19;
          then n < Sum vm by A2,A3,NUMERAL1:5;
          hence contradiction by A4,A1,A3,NUMERAL1:5;
        end;
        suppose A35: i<ldm1;
          i < len dm - 1 & len dm - 1 < len dm by A35,XREAL_1:44;
          then i < len dm by XXREAL_0:2;
          then A36: len (vm/^i) = len vm - i by A1,AFINSQ_2:7;
          A37: len (vm/^i) > 0 by A36,A13,A1,XREAL_1:50;
          then reconsider vmi=vm/^i as non empty XFinSequence of NAT;
          0 in Segm dom (vm/^i) by A37,NAT_1:44;
          then A38: vmi.0 = vm.(0+i) by AFINSQ_2:def 2;
          A39: vmi=<%vmi.0%>^(vmi/^1) by NUMERAL2:2;
          set c = Sum (vmi/^1);
          A40: Sum (vm/^i) = Sum <%vmi.0%> + c by A39,AFINSQ_2:55
          .= vm.i + c by A38,AFINSQ_2:53;

          i < len dn - 1 & len dn - 1 < len dn by A8,A35,XREAL_1:44;
          then i < len dn by XXREAL_0:2;
          then A41: len (vn/^i) = len vn - i by A2,AFINSQ_2:7;
          A42: len (vn/^i) > 0 by A8,A41,A13,A2,XREAL_1:50;
          then reconsider vni=vn/^i as non empty XFinSequence of NAT;
          0 in Segm dom (vn/^i) by A42,NAT_1:44;
          then A43: vni.0 = vn.(0+i) by AFINSQ_2:def 2;
          A44: vni=<%vni.0%>^(vni/^1) by NUMERAL2:2;
          set d = Sum (vni/^1);
          A45: Sum (vn/^i) = Sum <%vni.0%> + d by A44,AFINSQ_2:55
          .= vn.i + d by A43,AFINSQ_2:53;

          A46: len (vni/^1) = len vmi -' 1 by A41,A36,A2,A1,A8,AFINSQ_2:def 2;
          now
            let a be Nat;
            assume A47: a in dom (vni/^1);
            i <= (len vn) - 1 by A35,A2,A8;
            then len vn - i >= 1 by XREAL_1:11;
            then A48: len vni >= 1 by A41;
            len (vni/^1) = len vni -' 1 by AFINSQ_2:def 2;
            then len (vni/^1) = Segm (len vni - 1) by XREAL_1:233,A48;
            then a < len vni - 1 by NAT_1:44,A47;
            then A49: a+1 < len vni - 1 + 1 by XREAL_1:6;
            then A50: a+1 in Segm (dom vni) by NAT_1:44;

            a+1 < len vn - i by A41,A49;
            then A51: i+(a+1) < len vn - i + i by XREAL_1:6;
            then A52: i+(a+1) in Segm dom vn by NAT_1:44;
            i+(a+1) > i by XREAL_1:29;
            then A53: dn.(i+(a+1)) = dm.(i+(a+1)) by A13,A51,A2,A8;

            thus (vni/^1).a = vni.(a+1) by A47,AFINSQ_2:def 2
            .= vn.(i+(a+1)) by A50,AFINSQ_2:def 2
            .= dm.(i+(a+1))*b|^((i+(a+1))) by A53,A52,A2
            .= vm.(i+(a+1)) by A52,A1,A2,A8
            .= vmi.(a+1) by A36,A41,A8,A2,A1,A50,AFINSQ_2:def 2;
          end;
          then A54: vmi/^1 = vni/^1 by A46,AFINSQ_2:def 2;

          A55: dom (dn|i) c= dom dn & dom (vn|i) c= dom vn by RELAT_1:60;

          consider d9 being XFinSequence of NAT such that
          A56: (dom d9 = dom (dn|i) &
          for a being Nat st a in dom d9 holds d9.a = ((dn|i).a)*(b|^a))
          & value(dn|i,b) = Sum d9 by NUMERAL1:def 1;

          A57: dom d9 = i by A8,A56,A13,AFINSQ_1:54
          .= dom (vn|i) by A8,A2,A13,AFINSQ_1:54;

          now
            let a be Nat;
            assume A58: a in dom d9;
            then d9.a = ((dn|i).a)*(b|^a) by A56;
            then A59: d9.a = (dn.a)*(b|^a) by A58,A56,FUNCT_1:47;
            A60: a in dom (vn|i) by A58,A57;
            then A61: (vn|i).a=vn.a by FUNCT_1:47;
            a in dom vn by A60,A55;
            then (vn|i).a=(dn.a)*(b|^a) by A61,A2;
            hence d9.a=(vn|i).a by A59;
          end;
          then d9=vn|i by A57,AFINSQ_1:8;
          then A62: value(dn|i,b)=Sum(vn|i) by A56;

          A63: len (dn|i) > 0 by A8,A13,A16,AFINSQ_1:54;
          for a being Nat st a in dom (dn|i) holds (dn|i).a<b
          proof
            let a be Nat;
            assume a in dom (dn|i);
            then a in dom dn & (dn|i).a = dn.a by A55,FUNCT_1:47;
            hence (dn|i).a<b by A17,NUMERAL1:def 2,A3;
          end;
          then value(dn|i,b) < b|^(len(dn|i)) by A63,Th8,A3;
          then value(dn|i,b) < b|^i by A13,A8,AFINSQ_1:54;

          then Sum (vn|i) < b|^i by A62;
          then Sum (vn|i)+vn.i < b|^i + vn.i by XREAL_1:6;
          then Sum (vn|i)+vn.i < b|^i + (dn.i)*(b|^i) by A2,A15;
          then A64: Sum (vn|i)+vn.i < (b|^i)*(1 + (dn.i));

          1 + (dn.i) <= dm.i by A14,NAT_1:13;
          then (b|^i)*(1 + (dn.i)) <= (b|^i)*(dm.i) by XREAL_1:64;
          then (b|^i)*(1 + (dn.i)) <= vm.i by A15,A1;
          then Sum (vn|i)+vn.i < vm.i by A64,XXREAL_0:2;
          then Sum (vn|i)+(vn.i)+c < (vm.i)+c by XREAL_1:6;
          then Sum (vn|i)+Sum (vn/^i) < Sum (vm/^i) by A54,A40,A45;
          then Sum (vn|i)+Sum (vn/^i) < Sum (vm|i) + Sum (vm/^i) by XREAL_1:40;
          then Sum vn < Sum vm by A18,A19;
          then n < Sum vm by A2,A3,NUMERAL1:5;
          hence contradiction by A4,A1,A3,NUMERAL1:5;
        end;
      end;
      suppose A65: i=0;
        A66: len (dn/^1) = len dm -' 1 by A8,AFINSQ_2:def 2;
        for a being Nat st a in dom (dn/^1) holds (dn/^1).a = dm.(a+1)
        proof
          let a be Nat;
          assume A67: a in dom (dn/^1);
          len dm >= 1 by A3,NUMERAL1:4;
          then A68: len dm -' 1 = len dm - 1 by XREAL_1:233;
          a < Segm len (dn/^1) by A67,NAT_1:44;
          then A69: a+1 < len dm - 1 + 1 & a+1 > i
          by A66,A68,A65,XREAL_1:6;
          thus (dn/^1).a = dn.(a+1) by A67,AFINSQ_2:def 2
          .= dm.(a+1) by A69,A13;
        end;
        then A70: dm/^1 = dn/^1 by A66,AFINSQ_2:def 2;
        mid(dn,2,len dn) = dm/^1 by A70,NUMERAL2:3
        .= mid(dm,2,len dm) by NUMERAL2:3;
        then b*value(mid(dm,2,len dm),b) + dm.i >
             b*value(mid(dn,2,len dn),b) + dn.i by A14,XREAL_1:8;
        then m > b*value(mid(dn,2,len dn),b) + dn.i by A65,A3,NUMERAL2:19;
        hence contradiction by A4,A65,A3,NUMERAL2:19;
      end;
    end;
    thus thesis by A13;
  end;
  thus (len dm < len dn
  or len dm = len dn &
  ex i being Nat st i < len dm &
  dm.i < dn.i &
  for j being Nat st j < len dm & dm.j <> dn.j
  holds i>=j) implies m<n
  proof
    assume (len dm < len dn
    or len dm = len dn &
    ex i being Nat st i < len dm &
    dm.i < dn.i &
    for j being Nat st j < len dm & dm.j <> dn.j
    holds i>=j);
    then per cases;
    suppose
      A71: len dm < len dn;
      1 <= len dm by NUMERAL1:4,A3;
      then A72: len dn > 1 by A71,XXREAL_0:2;
      len digits(0,b) = len <%0%> by NUMERAL1:def 2,A3;
      then A73: n<>0 by A72,AFINSQ_1:34;
      m < b|^(len dm) & b|^(len dm) <= n by
      A3,A71,Th9,Th10,A73;
      hence m<n by XXREAL_0:2;
    end;
    suppose
      A74: len dm = len dn &
      ex i being Nat st i < len dm & dm.i < dn.i &
      for j being Nat st j < len dm & dm.j <> dn.j
      holds i>=j;
      then consider i being Nat such that
      A75: i < len dm & dm.i < dn.i &
      for j being Nat st j < len dm & dm.j <> dn.j
      holds i>=j;
      A76: i in Segm dom dm & i in Segm dom dn by A74,A75,NAT_1:44;

      per cases;
      suppose A77: i>0;
        A78:
        now
          assume m=0;
          then digits(m,b)=<%0%> by A3,NUMERAL1:def 2;
          then i < 1 & i >= 0+1 by A75,A77,AFINSQ_1:34,NAT_1:14;
          hence contradiction;
        end;

        vm = (vm|i)^(vm/^i);
        then A79: Sum vm = Sum (vm|i) + Sum (vm/^i) by AFINSQ_2:55;

        vn = (vn|i)^(vn/^i);
        then A80: Sum vn = Sum (vn|i) + Sum (vn/^i) by AFINSQ_2:55;

        len dm >= 0+1 by A3,NUMERAL1:4;
        then reconsider ldm1=len dm - 1 as Nat by NAT_1:20;
        i < ldm1 + 1 by A75;
        then i <= ldm1 by NAT_1:13;
        then per cases by XXREAL_0:1;
        suppose A81: i=ldm1;
          then i < len dm by XREAL_1:44;
          then A82: len (vm/^i) = len vm - i by A1,AFINSQ_2:7 .= 1 by A81,A1;
          then 0 in Segm dom (vm/^i) by NAT_1:44;
          then (vm/^i).0 = vm.(0+i) by AFINSQ_2:def 2;
          then (vm/^i) = <%vm.i%> by A82,AFINSQ_1:34;
          then A83: Sum (vm/^i) = vm.i by AFINSQ_2:53;

          i < len dm by A81,XREAL_1:44;
          then A84: len (vn/^i) = len vn - i
          by A74,A2,AFINSQ_2:7 .= 1 by A74,A81,A2;
          then 0 in Segm dom (vn/^i) by NAT_1:44;
          then (vn/^i).0 = vn.(0+i) by AFINSQ_2:def 2;
          then (vn/^i) = <%vn.i%> by A84,AFINSQ_1:34;
          then A85: Sum (vn/^i) = vn.i by AFINSQ_2:53;

          A86: dom (dm|i) c= dom dm & dom (vm|i) c= dom vm by RELAT_1:60;

          consider d9 being XFinSequence of NAT such that
          A87: (dom d9 = dom (dm|i) &
          for a being Nat st a in dom d9 holds d9.a = ((dm|i).a)*(b|^a))
          & value(dm|i,b) = Sum d9 by NUMERAL1:def 1;

          A88: dom d9 = i by A87,A75,AFINSQ_1:54
          .= dom (vm|i) by A1,A75,AFINSQ_1:54;

          now
            let a be Nat;
            assume A89: a in dom d9;
            then d9.a = ((dm|i).a)*(b|^a) by A87;
            then A90: d9.a = (dm.a)*(b|^a) by A89,A87,FUNCT_1:47;
            A91: a in dom (vm|i) by A89,A88;
            then A92: (vm|i).a=vm.a by FUNCT_1:47;
            a in dom vm by A91,A86;
            then (vm|i).a=(dm.a)*(b|^a) by A92,A1;
            hence d9.a=(vm|i).a by A90;
          end;
          then d9=vm|i by A88,AFINSQ_1:8;
          then A93: value(dm|i,b)=Sum(vm|i) by A87;

          A94: len (dm|i) > 0 by A75,A77,AFINSQ_1:54;
          for a being Nat st a in dom (dm|i) holds (dm|i).a<b
          proof
            let a be Nat;
            assume a in dom (dm|i);
            then a in dom dm & (dm|i).a = dm.a by A86,FUNCT_1:47;
            hence (dm|i).a<b by A78,NUMERAL1:def 2,A3;
          end;
          then value(dm|i,b) < b|^(len(dm|i)) by A94,Th8,A3;
          then value(dm|i,b) < b|^i by A75,AFINSQ_1:54;

          then Sum (vm|i) < b|^i by A93;
          then Sum (vm|i)+vm.i < b|^i + vm.i by XREAL_1:6;
          then Sum (vm|i)+vm.i < b|^i + (dm.i)*(b|^i) by A1,A76;
          then A95: Sum (vm|i)+vm.i < (b|^i)*(1 + (dm.i));

          1 + (dm.i) <= dn.i by A75,NAT_1:13;
          then (b|^i)*(1 + (dm.i)) <= (b|^i)*(dn.i) by XREAL_1:64;
          then (b|^i)*(1 + (dm.i)) <= vn.i by A76,A2;
          then Sum (vm|i)+vm.i < vn.i by A95,XXREAL_0:2;
          then Sum (vm|i)+Sum (vm/^i) < Sum (vn/^i) by A83,A85;
          then Sum (vm|i)+Sum (vm/^i) < Sum (vn|i) + Sum (vn/^i) by XREAL_1:40;
          then Sum vm < Sum vn by A79,A80;
          then m < Sum vn by A1,A3,NUMERAL1:5;
          hence m<n by A2,A3,NUMERAL1:5;
        end;
        suppose A96: i<ldm1;
          i < len dm - 1 & len dm - 1 < len dm by A96,XREAL_1:44;
          then i < len dm by XXREAL_0:2;
          then A97: len (vm/^i) = len vm - i by A1,AFINSQ_2:7;
          A98: len (vm/^i) > 0 by A97,A75,A1,XREAL_1:50;
          then reconsider vmi=vm/^i as non empty XFinSequence of NAT;
          0 in Segm dom (vm/^i) by A98,NAT_1:44;
          then A99: vmi.0 = vm.(0+i) by AFINSQ_2:def 2;
          A100: vmi=<%vmi.0%>^(vmi/^1) by NUMERAL2:2;
          set c = Sum (vmi/^1);
          A101: Sum (vm/^i) = Sum <%vmi.0%> + c by A100,AFINSQ_2:55
          .= vm.i + c by A99,AFINSQ_2:53;

          i < len dn - 1 & len dn - 1 < len dn by A74,A96,XREAL_1:44;
          then i < len dn by XXREAL_0:2;
          then A102: len (vn/^i) = len vn - i by A2,AFINSQ_2:7;
          A103: len (vn/^i) > 0 by A74,A102,A75,A2,XREAL_1:50;
          then reconsider vni=vn/^i as non empty XFinSequence of NAT;
          0 in Segm dom (vn/^i) by A103,NAT_1:44;
          then A104: vni.0 = vn.(0+i) by AFINSQ_2:def 2;
          A105: vni=<%vni.0%>^(vni/^1) by NUMERAL2:2;
          set d = Sum (vni/^1);
          A106: Sum (vn/^i) = Sum <%vni.0%> + d by A105,AFINSQ_2:55
          .= vn.i + d by A104,AFINSQ_2:53;

          A107: len (vni/^1)=len vmi -' 1 by A102,A97,A2,A1,A74,AFINSQ_2:def 2;
          now
            let a be Nat;
            assume A108: a in dom (vni/^1);
            i <= (len vn) - 1 by A96,A2,A74;
            then len vn - i >= 1 by XREAL_1:11;
            then A109: len vni >= 1 by A102;
            len (vni/^1) = len vni -' 1 by AFINSQ_2:def 2;
            then len (vni/^1) = Segm (len vni - 1) by XREAL_1:233,A109;
            then a < len vni - 1 by NAT_1:44,A108;
            then A110: a+1 < len vni - 1 + 1 by XREAL_1:6;
            then A111: a+1 in Segm (dom vni) by NAT_1:44;

            a+1 < len vn - i by A102,A110;
            then A112: i+(a+1) < len vn - i + i by XREAL_1:6;
            then A113: i+(a+1) in Segm dom vn by NAT_1:44;
            i+(a+1) > i by XREAL_1:29;
            then A114: dn.(i+(a+1)) = dm.(i+(a+1)) by A75,A112,A2,A74;

            thus (vni/^1).a = vni.(a+1) by A108,AFINSQ_2:def 2
            .= vn.(i+(a+1)) by A111,AFINSQ_2:def 2
            .= dm.(i+(a+1))*b|^((i+(a+1))) by A114,A113,A2
            .= vm.(i+(a+1)) by A113,A1,A2,A74
            .= vmi.(a+1) by A97,A102,A74,A2,A1,A111,AFINSQ_2:def 2;
          end;
          then A115: vmi/^1 = vni/^1 by A107,AFINSQ_2:def 2;

          A116: dom (dm|i) c= dom dm & dom (vm|i) c= dom vm by RELAT_1:60;

          consider d9 being XFinSequence of NAT such that
          A117: (dom d9 = dom (dm|i) &
          for a being Nat st a in dom d9 holds d9.a = ((dm|i).a)*(b|^a))
          & value(dm|i,b) = Sum d9 by NUMERAL1:def 1;

          A118: dom d9 = i by A117,A75,AFINSQ_1:54
          .= dom (vm|i) by A1,A75,AFINSQ_1:54;

          now
            let a be Nat;
            assume A119: a in dom d9;
            then d9.a = ((dm|i).a)*(b|^a) by A117;
            then A120: d9.a = (dm.a)*(b|^a) by A119,A117,FUNCT_1:47;
            A121: a in dom (vm|i) by A119,A118;
            then A122: (vm|i).a=vm.a by FUNCT_1:47;
            a in dom vm by A121,A116;
            then (vm|i).a=(dm.a)*(b|^a) by A122,A1;
            hence d9.a=(vm|i).a by A120;
          end;
          then d9=vm|i by A118,AFINSQ_1:8;
          then A123: value(dm|i,b)=Sum(vm|i) by A117;

          A124: len (dm|i) > 0 by A75,A77,AFINSQ_1:54;
          for a being Nat st a in dom (dm|i) holds (dm|i).a<b
          proof
            let a be Nat;
            assume a in dom (dm|i);
            then a in dom dm & (dm|i).a = dm.a by A116,FUNCT_1:47;
            hence (dm|i).a<b by A78,NUMERAL1:def 2,A3;
          end;
          then value(dm|i,b) < b|^(len(dm|i)) by A124,Th8,A3;
          then value(dm|i,b) < b|^i by A75,AFINSQ_1:54;

          then Sum (vm|i) < b|^i by A123;
          then Sum (vm|i)+vm.i < b|^i + vm.i by XREAL_1:6;
          then Sum (vm|i)+vm.i < b|^i + (dm.i)*(b|^i) by A1,A76;
          then A125: Sum (vm|i)+vm.i < (b|^i)*(1 + (dm.i));

          1 + (dm.i) <= dn.i by A75,NAT_1:13;
          then (b|^i)*(1 + (dm.i)) <= (b|^i)*(dn.i) by XREAL_1:64;
          then (b|^i)*(1 + (dm.i)) <= vn.i by A76,A2;
          then Sum (vm|i)+vm.i < vn.i by A125,XXREAL_0:2;
          then Sum (vm|i)+(vm.i)+c < (vn.i)+c by XREAL_1:6;
          then Sum (vm|i)+Sum (vm/^i) < Sum (vn/^i) by A115,A101,A106;
          then Sum (vm|i)+Sum (vm/^i) < Sum (vn|i) + Sum (vn/^i) by XREAL_1:40;
          then Sum vm < Sum vn by A79,A80;
          then m < Sum vn by A1,A3,NUMERAL1:5;
          hence m<n by A2,A3,NUMERAL1:5;
        end;
      end;
      suppose A126: i=0;
        A127: len (dn/^1) = len dm -' 1 by A74,AFINSQ_2:def 2;
        for a being Nat st a in dom (dn/^1) holds (dn/^1).a = dm.(a+1)
        proof
          let a be Nat;
          assume A128: a in dom (dn/^1);
          len dm >= 1 by A3,NUMERAL1:4;
          then A129: len dm -' 1 = len dm - 1 by XREAL_1:233;
          a < Segm len (dn/^1) by A128,NAT_1:44;
          then A130: a+1 < len dm - 1 + 1 & a+1 > i
          by A127,A129,A126,XREAL_1:6;
          thus (dn/^1).a = dn.(a+1) by A128,AFINSQ_2:def 2
          .= dm.(a+1) by A130,A75;
        end;
        then A131: dm/^1 = dn/^1 by A127,AFINSQ_2:def 2;
        mid(dm,2,len dm) = dn/^1 by A131,NUMERAL2:3
        .= mid(dn,2,len dn) by NUMERAL2:3;
        then b*value(mid(dn,2,len dn),b) + dn.i >
             b*value(mid(dm,2,len dm),b) + dm.i by A75,XREAL_1:8;
        then n > b*value(mid(dm,2,len dm),b) + dm.i by A126,A3,NUMERAL2:19;
        hence m<n by A126,A3,NUMERAL2:19;
      end;
    end;
  end;
end;
