
theorem Th12:
  for I being non empty set for A be PLS-yielding ManySortedSet of
I for L being Segre-like non trivial-yielding ManySortedSubset of Carrier A for
  B being Block of A.indx(L) holds product(L+*(indx(L),B)) is Block of
  Segre_Product A
proof
  let I being non empty set;
  let A be PLS-yielding ManySortedSet of I;
  let L being Segre-like non trivial-yielding ManySortedSubset of Carrier A;
  let B being Block of A.indx(L);
  B in the topology of A.indx(L);
  then reconsider B1=B as Subset of A.indx(L);
A1: now
    let i be Element of I;
    assume
A2: i <> indx(L);
    then L+*(indx(L),B1).i = L.i by FUNCT_7:32;
    hence L+*(indx(L),B1).i is 1-element by A2,PENCIL_1:12;
  end;
  2 c= card B by PENCIL_1:def 6;
  then B1 is non trivial by PENCIL_1:4;
  then reconsider S=L+*(indx(L),B1) as Segre-like non trivial-yielding
  ManySortedSubset of Carrier A by A1,PENCIL_1:9,def 20,PENCIL_2:7;
A3: now
    assume indx(S)<>indx(L);
    then S.indx(S) is 1-element by A1;
    hence contradiction by PENCIL_1:def 21;
  end;
  dom L = I by PARTFUN1:def 2;
  then S.indx(S) = B1 by A3,FUNCT_7:31;
  hence thesis by A3,PENCIL_1:24;
end;
