reserve U1,U2,U3 for Universal_Algebra,
  n,m for Nat,
  x,y,z for object,
  A,B for non empty set,
  h1 for FinSequence of [:A,B:];
reserve h1 for homogeneous quasi_total non empty PartFunc of
    (the carrier of U1)*,the carrier of U1,
  h2 for homogeneous quasi_total non empty PartFunc of
    (the carrier of U2)*,the carrier of U2;

theorem
  for f,g be 1-sorted-yielding Function holds
    f tolerates g implies Carrier f tolerates Carrier g
proof
  let f,g be 1-sorted-yielding Function;
  assume A1: f tolerates g;
  now
    let x be object;
    assume x in dom Carrier f /\ dom Carrier g;
    then x in dom Carrier f /\ dom g by Def13;
    then A2: x in dom f /\ dom g & x is set by Def13;
    then A3: x in dom f & x in dom g by XBOOLE_0:def 4;
A4: f.x = g.x by A1, A2, PARTFUN1:def 4;
    consider R1 being 1-sorted such that
A5: R1 = f.x & (Carrier f).x = the carrier of R1 by A3, Def13;
    consider R2 being 1-sorted such that
A6: R2 = g.x & (Carrier g).x = the carrier of R2 by A3, Def13;
    thus (Carrier f).x = (Carrier g).x by A4, A5, A6;
  end;
  hence thesis by PARTFUN1:def 4;
end;
