reserve n,m,k,k1,k2 for Nat;
reserve X for non empty Subset of ExtREAL;
reserve Y for non empty Subset of REAL;
reserve seq for ExtREAL_sequence;
reserve e1,e2 for ExtReal;
reserve rseq for Real_Sequence;

theorem Th12:
  seq = rseq implies (seq is bounded_above iff rseq is bounded_above)
proof
  assume
A1: seq=rseq;
  hereby
    assume seq is bounded_above;
    then rng rseq is bounded_above by A1;
    then consider p be Real such that
A2:   p is UpperBound of rng rseq by XXREAL_2:def 10;
A3: for y be Real st y in rng rseq holds y <= p by A2,XXREAL_2:def 1;
    now
      let n be Nat;
      n in NAT by ORDINAL1:def 12;
      then rseq.n in rng rseq by FUNCT_2:4;
      then 0 + rseq.n < 1+ p by A3,XREAL_1:8;
      hence rseq.n < p+1;
    end;
    hence rseq is bounded_above by SEQ_2:def 3;
  end;
  assume rseq is bounded_above;
  then consider q be Real such that
A4: for n be Nat holds rseq.n < q by SEQ_2:def 3;
  now
    let r be ExtReal;
    assume r in rng seq;
    then ex x be object st x in dom rseq & r=rseq.x by A1,FUNCT_1:def 3;
    hence r <= q by A4;
  end;
  then q is UpperBound of rng seq by XXREAL_2:def 1;
  hence rng seq is bounded_above by XXREAL_2:def 10;
end;
