reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem Th12:
  for L be Linear_Combination of I st L is convex & Carrier L = I holds
    Sum L in Int I
  proof
    let L be Linear_Combination of I such that
    A1: L is convex and
    A2: Carrier L=I;
    reconsider I1=I as non empty Subset of V by A1,A2,CONVEX1:21;
    reconsider K=L as Linear_Combination of I1;
    K in ConvexComb(V) by A1,CONVEX3:def 1;
    then Sum K in {Sum M where M is Convex_Combination of I1:
      M in ConvexComb(V)} by A1;
    then A3: Sum K in conv I1 by CONVEX3:5;
    A4: conv I1 c=Affin I1 & sum L=1 by A1,RLAFFIN1:62,65;
    for A be Subset of V st A c<I holds not Sum K in conv A
    proof
      let A be Subset of V such that
      A5: A c<I;
      assume A6: Sum K in conv A;
      conv A c=Affin A & A c=I by A5,RLAFFIN1:65;
      then (Sum K)|--A=(Sum K)|--I by A6,RLAFFIN1:77
      .=K by A3,A4,RLAFFIN1:def 7;
      then I c=A by A2,RLVECT_2:def 6;
      hence thesis by A5,XBOOLE_0:def 8;
    end;
    hence thesis by A3,Def1;
  end;
