 reserve L for non empty LattStr;
 reserve v64,v65,v66,v67,v103,v3,v102,v101,v100,v2,v1,v0 for Element of L;
 reserve L for distributive join-commutative meet-commutative
   non empty LattStr;
 reserve v0,v1,v2 for Element of L;

theorem Combined:
  for L being non empty LattStr holds
    L is distributive Lattice iff
      L is join-absorbing satisfying_Sholander_1
  proof
    let L be non empty LattStr;
    thus L is distributive Lattice implies
      L is join-absorbing satisfying_Sholander_1 by LatToSho;
    assume
A1: L is join-absorbing satisfying_Sholander_1; then
A2: for v0,v2,v1 being Element of L
      holds v0 "/\" (v1 "\/" v2) = (v2 "/\" v0) "\/" (v1 "/\" v0);
    then
A3: L is distributive by Seventh,A1;
A4: L is meet-commutative join-commutative by A2,A1,MeetCom,JoinCom;
A5: L is meet-associative join-associative by A2,A1,MeetAssoc,JoinAssoc;
    for v0,v1 being Element of L holds
      (v0 "/\" v1) "\/" v1 = v1
    proof
      let v0,v1 be Element of L;
      (v0 "/\" v1) "\/" v1 = v1 "\/" (v0 "/\" v1) by A4
         .= v1 "\/" (v1 "/\" v0) by A4
         .= v1 by MeetAbsor,A1,A2;
      hence thesis;
    end; then
    L is meet-absorbing;
    hence thesis by A3,A4,A5,A1;
  end;
