reserve x,y,X for set,
        r for Real,
        n,k for Nat;
reserve RLS for non empty RLSStruct,
        Kr,K1r,K2r for SimplicialComplexStr of RLS,
        V for RealLinearSpace,
        Kv for non void SimplicialComplex of V;

theorem Th12:
  Complex_of the topology of Kr is SubdivisionStr of Kr
 proof
  set TOP=the topology of Kr;
  set C=Complex_of TOP;
  [#]C=[#]Kr & [#]Kr c=the carrier of RLS by SIMPLEX0:def 9;
  then reconsider C as SimplicialComplexStr of RLS by SIMPLEX0:def 9;
  A1: |.Kr.|c=|.C.|
  proof
   let x be object;
   assume x in |.Kr.|;
   then consider A be Subset of Kr such that
    A2: A is simplex-like and
    A3: x in conv@A by Def3;
   reconsider B=A as Subset of C;
   A in TOP by A2;
   then A in the topology of C by SIMPLEX0:2;
   then A4: B is simplex-like;
   @A=@B;
   hence thesis by A3,A4,Def3;
  end;
  for A be Subset of C st A is simplex-like ex B be Subset of Kr st B is
simplex-like & conv@A c=conv@B
  proof
   let A be Subset of C;
   assume A is simplex-like;
   then A in the topology of C;
   then consider B be set such that
    A5: A c=B and
    A6: B in TOP by SIMPLEX0:2;
   reconsider B as Subset of Kr by A6;
   take B;
   thus thesis by A5,A6,RLAFFIN1:3;
  end;
  hence thesis by A1,Def4;
 end;
