reserve X for set;
reserve S for Subset-Family of X;

theorem Thm6:
  for S be diff-c=-finite-partition-closed cap-finite-partition-closed
  Subset-Family of X holds S is diff-finite-partition-closed
  proof
    let S be diff-c=-finite-partition-closed
    cap-finite-partition-closed Subset-Family of X;
    for S1,S2 be Element of S st S1\S2 is non empty holds
    ex P0 be finite Subset of S st P0 is a_partition of S1\S2
    proof
      let S1,S2 be Element of S;
      assume
      S1\S2 is non empty;
      consider P0 be finite Subset of S such that
A1:   P0 is a_partition of S1/\S2 by Lem7;
A2:   union P0 c= S1
      proof
        let x be object;
        assume x in union P0;
        then consider x0 be set such that
A3:     x in x0 & x0 in P0 by TARSKI:def 4;
        S1/\S2 c= S1 by XBOOLE_1:17;
        then x0 c= S1 by A1,A3,XBOOLE_1:1;
        hence thesis by A3;
      end;
      P0 is a_partition of union P0 by A1,EQREL_1:def 4;
      then consider R be finite Subset of S such that
      union R misses union P0 and
A4:   P0\/R is a_partition of S1 by A2,Thm5;
A5:   R/\bool(S1\S2) is finite Subset of S &
      R/\bool(S1\S2) is a_partition of S1 \ S2
      proof
A6:     R/\bool(S1\S2) is Subset-Family of S1 \ S2 by XBOOLE_1:17;
A7:     union (R/\bool(S1\S2)) = S1\S2
        proof
A8:       union (R/\bool(S1\S2)) c= S1\S2
          proof
            union (R/\bool(S1\S2)) c= union bool (S1\S2)
            by XBOOLE_1:17,ZFMISC_1:77;
            hence thesis by ZFMISC_1:81;
          end;
          S1\S2 c= union(R/\bool(S1\S2))
          proof
            let x be object;
            assume
A9:         x in S1\S2;
            then
            x in S1 & not x in S2 by XBOOLE_0:def 5;
             then x in union (P0\/R) by A4,EQREL_1:def 4;
            then consider X0 be set such that
A10:        x in X0 and
A11:        X0 in P0\/R by TARSKI:def 4;
A12:        X0 in P0 implies X0 in bool S2
            proof
              assume
A13:          X0 in P0;
              S1/\S2 c= S2 by XBOOLE_1:17;
              then X0 c= S2 by A13,A1,XBOOLE_1:1;
              hence thesis;
            end;
            X0 in R/\bool(S1\S2)
            proof
A14:          X0 in R by A12,A9,XBOOLE_0:def 5,A10,A11,XBOOLE_0:def 3;
              X0 c= S1\S2
              proof
                assume not X0 c= S1\S2;
                then consider xx be object such that
A15:            xx in X0 and
A16:            not xx in S1\S2 by TARSKI:def 3;
                xx in X0 & X0 in R
                by A12,A9,XBOOLE_0:def 5,A10,A11,XBOOLE_0:def 3,A15;
                then
A17:            xx in union R by TARSKI:def 4;
                union R c= union (P0\/R) by XBOOLE_1:7,ZFMISC_1:77;
                then
A18:            union R c= S1 by A4,EQREL_1:def 4;
A19:            not xx in S1 or xx in S2 by A16,XBOOLE_0:def 5;
                X0 in P0
                proof
A20:              xx in S1/\S2 by A18,A17,A19,XBOOLE_0:def 4;
                  union P0=S1/\S2 by A1,EQREL_1:def 4;
                  then consider PP be set such that
A21:              xx in PP and
A22:              PP in P0 by A20,TARSKI:def 4;
A23:              xx in PP/\X0 by A21,A15,XBOOLE_0:def 4;
                  PP in P0\/R & X0 in P0\/R by A22,XBOOLE_0:def 3,A11;
                  hence thesis by A22,A4,A23,XBOOLE_0:def 7,EQREL_1:def 4;
                end;
                hence thesis by A10,A12,A9,XBOOLE_0:def 5;
              end;
              hence thesis by A14,XBOOLE_0:def 4;
            end;
            hence thesis by A10,TARSKI:def 4;
          end;
          hence thesis by A8;
        end;
        for A be Subset of S1\S2 st A in R/\bool(S1\S2) holds A<>{} &
        for B be Subset of S1\S2 st B in R/\bool(S1\S2) holds A=B or A misses B
        proof
          let A be Subset of S1\S2 such that
A24:      A in R/\bool(S1\S2);
          A in R by A24,XBOOLE_0:def 4;
          then
A25:      A in P0\/R by XBOOLE_0:def 3;
          now
            let B be Subset of S1\S2 such that
A26:        B in R/\bool(S1\S2);
            B in R by A26,XBOOLE_0:def 4;
            then B in P0\/R by XBOOLE_0:def 3;
            hence A=B or A misses B by A25,A4,EQREL_1:def 4;
          end;
          hence thesis by A25,A4;
        end;
        hence thesis by A6,A7,EQREL_1:def 4;
      end;
      thus thesis by A5;
     end;
    hence thesis;
  end;
