reserve K,F for Ring;
reserve V,W for VectSp of K;
reserve l for Linear_Combination of V;
reserve T for linear-transformation of V,W;

theorem
  for K being Ring,
  V, U being VectSp of K, f being linear-transformation of V,U holds
  ex T being linear-transformation of VectQuot(V,ker f), im f
  st T = CQFunctional(f) & T is bijective
  proof
    let K be Ring,
    V, U be VectSp of K, f be linear-transformation of V,U;
    set T = CQFunctional(f);
    set Vq = VectQuot(V,ker f);
    Q0: the carrier of im f = [#] im f
    .= f.: [#]V by RANKNULL:def 2
    .= f.: (dom f) by FUNCT_2:def 1
    .= rng f by RELAT_1:113;
    Q1: for x being object holds x in rng T iff x in rng f
    proof
      let x be object;
      hereby
        assume x in rng T;
        then consider z be object such that
        Q12: z in dom T & x = T.z by FUNCT_1:def 3;
        reconsider z as Vector of Vq by Q12;
        consider a be Vector of V such that
        A14: z = a+(ker f) by VECTSP10:22;
        T.z = f.a by A14,Def12;
        hence x in rng f by Q12,FUNCT_2:4;
      end;
      assume x in rng f;
      then consider a be object such that
      Q12: a in dom f & x = f.a by FUNCT_1:def 3;
      reconsider a as Vector of V by Q12;
      reconsider z = a+ ker f as Vector of Vq by VECTSP10:23;
      T.z = f.a by Def12;
      hence x in rng T by Q12,FUNCT_2:4;
    end; then
    P1: rng T = the carrier of im f by Q0,TARSKI:2;
    the carrier of (VectQuot(V,ker f)) = dom T by FUNCT_2:def 1;
    then reconsider T as Function of
    the carrier of (VectQuot(V,ker f)),the carrier of im f by FUNCT_2:2,P1;
    A1: T is onto by Q0,Q1,TARSKI:2;
    set Tq = CQFunctional(f);
    now
      let A, B be Vector of Vq;
      thus T.(A+B) = (Tq.A) +(Tq.B) by VECTSP_1:def 20
      .=T.A + T.B by VECTSP_4:13;
    end; then
    AD: T is additive;
    now
      let A be Vector of Vq;
      let r be Element of K;
      thus T.(r*A) = r*Tq.A by MOD_2:def 2
      .= r*(T.A) by VECTSP_4:14;
    end;
    then T is homogeneous;
    then reconsider T as linear-transformation of Vq, im f by AD;
    take T;
    thus thesis by A1;
  end;
