
theorem Th12:
  for L being complete continuous LATTICE, T being Scott
  TopAugmentation of L holds T is injective
proof
  let L be complete continuous LATTICE, T be Scott TopAugmentation of L;
  let X be non empty TopSpace, f be Function of X, T such that
A1: f is continuous;
  let Y be non empty TopSpace such that
A2: X is SubSpace of Y;
  deffunc F(set) = "\/" ({inf (f.:(V /\ the carrier of X)) where V is open
  Subset of Y: $1 in V},T);
  consider g being Function of the carrier of Y, the carrier of T such that
A3: for x being Element of Y holds g.x = F(x) from FUNCT_2:sch 4;
  reconsider g as Function of Y, T;
  take g;
A4: dom f = the carrier of X by FUNCT_2:def 1;
A5: for P being Subset of T st P is open holds g"P is open
  proof
    let P be Subset of T;
    assume P is open;
    then reconsider P as open Subset of T;
    for x being set holds x in g"P iff ex Q being Subset of Y st Q is open
    & Q c= g"P & x in Q
    proof
      let x be set;
      thus x in g"P implies ex Q being Subset of Y st Q is open & Q c= g"P & x
      in Q
      proof
        assume
A6:     x in g"P;
        then reconsider y = x as Point of Y;
        set A = {inf (f.: (V /\ the carrier of X)) where V is open Subset of Y
        : y in V};
        A c= the carrier of T
        proof
          let a be object;
          assume a in A;
          then
          ex V being open Subset of Y st a = inf (f.:(V /\ the carrier of
          X)) & y in V;
          hence thesis;
        end;
        then reconsider A as Subset of T;
A7:     inf (f.:([#]Y /\ the carrier of X)) in A;
A8:     A is directed
        proof
          let a, b be Element of T;
          assume a in A;
          then consider Va being open Subset of Y such that
A9:       a = inf (f.:(Va /\ the carrier of X)) and
A10:      y in Va;
          assume b in A;
          then consider Vb being open Subset of Y such that
A11:      b = inf (f.:(Vb /\ the carrier of X)) and
A12:      y in Vb;
          take inf (f.:(Va /\ Vb /\ the carrier of X));
          y in Va /\ Vb by A10,A12,XBOOLE_0:def 4;
          hence inf (f.:(Va /\ Vb /\ the carrier of X)) in A;
          Va /\ Vb /\ the carrier of X c= Vb /\ the carrier of X by XBOOLE_1:17
,26;
          then
A13:      f.:(Va /\ Vb /\ the carrier of X) c= f.:(Vb /\ the carrier of X
          ) by RELAT_1:123;
          Va /\ Vb /\ the carrier of X c= Va /\ the carrier of X by XBOOLE_1:17
,26;
          then
          f.:(Va /\ Vb /\ the carrier of X) c= f.:(Va /\ the carrier of X
          ) by RELAT_1:123;
          hence thesis by A9,A11,A13,WAYBEL_7:1;
        end;
A14:    g.y = sup A by A3;
        g.y in P by A6,FUNCT_2:38;
        then A meets P by A14,A7,A8,WAYBEL11:def 1;
        then consider b being object such that
A15:    b in A and
A16:    b in P by XBOOLE_0:3;
        consider B being open Subset of Y such that
A17:    b = inf (f.:(B /\ the carrier of X)) and
A18:    y in B by A15;
        reconsider b as Element of T by A17;
        take B;
        thus B is open;
        thus B c= g"P
        proof
          let a be object;
          assume
A19:      a in B;
          then reconsider a as Point of Y;
A20:      g.a = F(a) by A3;
          b in {inf (f.:(V /\ the carrier of X)) where V is open Subset
          of Y : a in V} by A17,A19;
          then b <= g.a by A20,YELLOW_2:22;
          then g.a in P by A16,WAYBEL_0:def 20;
          hence thesis by FUNCT_2:38;
        end;
        thus thesis by A18;
      end;
      thus thesis;
    end;
    hence thesis by TOPS_1:25;
  end;
  set gX = g|(the carrier of X);
A21: the carrier of X c= the carrier of Y by A2,BORSUK_1:1;
A22: for a being object st a in the carrier of X holds gX.a = f.a
  proof
    let a be object;
    assume
 a in the carrier of X;
    then reconsider x = a as Point of X;
    reconsider y = x as Point of Y by A21;
    set A = {inf (f.:(V /\ the carrier of X)) where V is open Subset of Y: y
    in V};
    A c= the carrier of T
    proof
      let a be object;
      assume a in A;
      then
      ex V being open Subset of Y st a = inf (f.:(V /\ the carrier of X )
      ) & y in V;
      hence thesis;
    end;
    then reconsider A as Subset of T;
A23: f.x is_>=_than A
    proof
      let z be Element of T;
      assume z in A;
      then consider V being open Subset of Y such that
A24:  z = inf (f.:(V /\ the carrier of X)) and
A25:  y in V;
A26:  ex_inf_of f.:(V /\ the carrier of X),T by YELLOW_0:17;
      y in V /\ the carrier of X by A25,XBOOLE_0:def 4;
      hence z <= f.x by A24,A26,FUNCT_2:35,YELLOW_4:2;
    end;
A27: for b being Element of T st b is_>=_than A holds f.x <= b
    proof
      let b be Element of T such that
A28:  for k being Element of T st k in A holds k <= b;
A29:  for V being open Subset of X st x in V holds inf (f.:V) <= b
      proof
        let V be open Subset of X;
        V in the topology of X by PRE_TOPC:def 2;
        then consider Q being Subset of Y such that
A30:    Q in the topology of Y and
A31:    V = Q /\ [#]X by A2,PRE_TOPC:def 4;
        reconsider Q as open Subset of Y by A30,PRE_TOPC:def 2;
        assume x in V;
        then y in Q by A31,XBOOLE_0:def 4;
        then inf (f.:(Q /\ the carrier of X)) in A;
        hence thesis by A28,A31;
      end;
A32:  b is_>=_than waybelow f.x
      proof
        let w be Element of T;
A33:    wayabove w is open by WAYBEL11:36;
A34:    ex_inf_of f.:f"wayabove w,T by YELLOW_0:17;
A35:    w <= inf wayabove w by WAYBEL14:9;
        ex_inf_of wayabove w,T by YELLOW_0:17;
        then inf wayabove w <= inf (f.:f"wayabove w) by A34,FUNCT_1:75
,YELLOW_0:35;
        then
A36:    w <= inf (f.:f"wayabove w) by A35,ORDERS_2:3;
        assume w in waybelow f.x;
        then w << f.x by WAYBEL_3:7;
        then f.x in wayabove w by WAYBEL_3:8;
        then
A37:    x in f"wayabove w by FUNCT_2:38;
        [#]T <> {};
        then f"wayabove w is open by A1,A33,TOPS_2:43;
        then inf (f.:f"wayabove w) <= b by A29,A37;
        hence w <= b by A36,ORDERS_2:3;
      end;
      f.x = sup waybelow f.x by WAYBEL_3:def 5;
      hence thesis by A32,YELLOW_0:32;
    end;
    thus gX.a = g.y by FUNCT_1:49
      .= F(y) by A3
      .= f.a by A23,A27,YELLOW_0:30;
  end;
  [#]T <> {};
  hence g is continuous by A5,TOPS_2:43;
  dom gX = dom g /\ the carrier of X by RELAT_1:61
    .= (the carrier of Y) /\ the carrier of X by FUNCT_2:def 1
    .= the carrier of X by A2,BORSUK_1:1,XBOOLE_1:28;
  hence thesis by A4,A22,FUNCT_1:2;
end;
