 reserve x, y, y1, y2 for set;
 reserve V for Z_Module;
 reserve u, v, w for Vector of V;
 reserve F, G, H, I for FinSequence of V;
 reserve W, W1, W2, W3 for Submodule of V;
 reserve KL1, KL2 for Linear_Combination of V;
 reserve X for Subset of V;

theorem Th12:
  for K being Linear_Combination of W holds
  ex L being Linear_Combination of V st
  Carrier(K) = Carrier(L) & Sum(K) = Sum(L)
  proof
    let K be Linear_Combination of W;
    defpred P[object, object] means
     ($1 in W & $2 = K.$1) or (not $1 in W & $2 = 0);
    reconsider K9= K as Function of the carrier of W, INT;
    A1: the carrier of W c= the carrier of V by VECTSP_4:def 2;
    then reconsider C = Carrier(K) as finite Subset of V by XBOOLE_1:1;
    A2: for x being object st x in the carrier of V
    ex y being object st y in INT & P[x, y]
    proof
      let x be object;
      assume x in the carrier of V;
      then reconsider x as Vector of V;
      per cases;
      suppose
        A3: x in W;
        then reconsider x as Vector of W;
        P[x, K.x] by A3;
        hence thesis;
      end;
      suppose
        A4: not x in W;
        thus thesis by A4;
      end;
    end;
    consider L being Function of the carrier of V, INT such that
A5: for x being object st x in the carrier of V holds P[x, L.x]
      from FUNCT_2:sch 1(A2);
    A6:
    now
      let v be Vector of V;
      assume not v in C;
      then P[v, K.v] & not v in C & v in the carrier of W or P[v, 0]
      by STRUCT_0:def 5;
      then P[v, K.v] & K.v = 0 or P[v, 0];
      hence L.v = 0 by A5;
    end;
    L is Element of Funcs(the carrier of V, the carrier of INT.Ring)
      by FUNCT_2:8;
    then reconsider L as Linear_Combination of V by A6,VECTSP_6:def 1;
    reconsider L9= L|the carrier of W as Function of the carrier of W, INT
    by A1,FUNCT_2:32;
    take L;
    now
      let x be object;
      assume that
      A7: x in Carrier(L) and
      A8: not x in the carrier of W;
      consider v being Vector of V such that
      A9: x = v and
      A10: L.v <> 0 by A7;
      P[v, 0] by A8,A9,STRUCT_0:def 5;
      hence contradiction by A5,A10;
    end;
    then
    A11: Carrier(L) c= the carrier of W;
    now
      let x be object;
      assume
      A12: x in the carrier of W;
      then P[x, L.x] by A5,A1;
      hence K9.x = L9.x by A12,FUNCT_1:49,STRUCT_0:def 5;
    end;
    then K9 = L9 by FUNCT_2:12;
    hence thesis by A11,Th11;
  end;
