reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem
  for f be PartFunc of CNS,CNS, Y be Subset of CNS st Y c= dom f & f|Y =
  id Y holds f is_continuous_on Y
proof
  let f be PartFunc of CNS,CNS;
  let Y be Subset of CNS;
  assume that
A1: Y c= dom f and
A2: f|Y = id Y;
  now
    let x1,x2 be Point of CNS;
    assume that
A3: x1 in Y and
A4: x2 in Y;
    x1 in dom f /\ Y by A1,A3,XBOOLE_0:def 4;
    then
A5: x1 in dom (f|Y) by RELAT_1:61;
    (f|Y).x1 = x1 by A2,A3,FUNCT_1:17;
    then f.x1 = x1 by A5,FUNCT_1:47;
    then
A6: f/.x1 = x1 by A1,A3,PARTFUN1:def 6;
    x2 in dom f /\ Y by A1,A4,XBOOLE_0:def 4;
    then
A7: x2 in dom (f|Y) by RELAT_1:61;
    (f|Y).x2 = x2 by A2,A4,FUNCT_1:17;
    then f.x2 = x2 by A7,FUNCT_1:47;
    hence ||. f/.x1-f/.x2.|| <= 1*||. x1-x2.|| by A1,A4,A6,PARTFUN1:def 6;
  end;
  then f is_Lipschitzian_on Y by A1;
  hence thesis by Th116;
end;
