reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem
  for f be PartFunc of CNS,CNS, z be Complex, p be Point of CNS st X c=
  dom f & (for x0 be Point of CNS st x0 in X holds f/.x0 = z*x0+p) holds f
  is_continuous_on X
proof
  let f be PartFunc of CNS,CNS;
  let z be Complex;
  let p be Point of CNS;
  assume that
A1: X c= dom f and
A2: for x0 be Point of CNS st x0 in X holds f/.x0 = z*x0+p;
  now
    0 + 0 < |.z.| + 1 by COMPLEX1:46,XREAL_1:8;
    hence 0 < |.z.|+1;
    let x1,x2 be Point of CNS;
    assume x1 in X & x2 in X;
    then f/.x1 = z*x1+p & f/.x2 = z*x2+p by A2;
    then
A3: ||. f/.x1-f/.x2.|| = ||. z*x1+(p-(p+z*x2)).|| by RLVECT_1:28
      .= ||. z*x1+(p-p-z*x2).|| by RLVECT_1:27
      .= ||. z*x1+(0.CNS-z*x2).|| by RLVECT_1:15
      .= ||. z*x1+-z*x2.|| by RLVECT_1:14
      .= ||. z*x1-z*x2.|| by RLVECT_1:def 11
      .= ||. z*(x1-x2).|| by CLVECT_1:9
      .= |.z.|*||. x1-x2.|| by CLVECT_1:def 13;
    0<=||. x1-x2.|| by CLVECT_1:105;
    then ||. f/.x1-f/.x2.|| + 0 <= |.z.|*||. x1-x2.|| + 1*||. x1-x2.|| by A3,
XREAL_1:7;
    hence ||. f/.x1-f/.x2.|| <= (|.z.|+1)*||. x1-x2.||;
  end;
  then f is_Lipschitzian_on X by A1;
  hence thesis by Th116;
end;
