reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th132:
  for f be PartFunc of the carrier of CNS,REAL st (for x0 be
Point of CNS st x0 in dom f holds f/.x0 = ||. x0.|| ) holds f is_continuous_on
  dom f
proof
  let f be PartFunc of the carrier of CNS,REAL;
  assume
A1: for x0 be Point of CNS st x0 in dom f holds f/.x0 = ||. x0 .||;
  now
    let x1,x2 be Point of CNS;
    ||. x2 .|| - ||. x1 .|| <= ||.x2 - x1.|| by CLVECT_1:109;
    then ||. x2 .|| - ||. x1 .|| <= ||.x1 - x2.|| by CLVECT_1:108;
    then
A2: ||. x1 .|| - ||. x2 .|| <= ||.x1 - x2.|| & -(-(||. x1 .|| - ||. x2 .||
    )) >= - (||.x1 - x2.||) by CLVECT_1:109,XREAL_1:24;
    assume x1 in dom f & x2 in dom f;
    then f/.x1 = ||. x1 .|| & f/.x2 = ||. x2 .|| by A1;
    hence |.f/.x1 - f/.x2.| <= 1*||. x1 - x2 .|| by A2,ABSVALUE:5;
  end;
  then f is_Lipschitzian_on dom f;
  hence thesis by Th120;
end;
