
theorem Th134:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`1=b & p2`2=
c & p3`2= c & p4`2= c & c <=p1`2 & p1`2<=d & b>=p2`1 & p2`1>p3`1 & p3`1>p4`1 &
p4`1> a & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one & g is
continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) & rng g c=
  closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`1=b and
A4: p2`2= c and
A5: p3`2= c and
A6: p4`2= c and
A7: c <=p1`2 and
A8: p1`2<=d and
A9: b>=p2`1 and
A10: p2`1>p3`1 and
A11: p3`1>p4`1 and
A12: p4`1> a and
A13: f.0=p1 and
A14: f.1=p3 and
A15: g.0=p2 and
A16: g.1=p4 and
A17: f is continuous one-to-one and
A18: g is continuous one-to-one and
A19: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A20: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A21: p2`1>p4`1 by A10,A11,XXREAL_0:2;
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A22: -1 <=((f2).O)`2 by A1,A2,A3,A7,A8,A13,Th66;
A23: ((f2).O)`1= 1 by A1,A3,A13,Th56;
A24: f2 is continuous one-to-one by A1,A2,A17,Th53;
A25: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A19,Th52;
A26: ((f2).I)`2= -1 by A2,A5,A14,Th57;
A27: ((f2).O)`2<=1 by A1,A2,A3,A7,A8,A13,Th66;
  set x = the Element of rng f2 /\ rng g2;
A28: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A29: h.p3=f2.I by A14,FUNCT_1:13;
  d-c >0 by A2,XREAL_1:50;
  then
A30: C >0 by XREAL_1:139;
  b-a>0 by A1,XREAL_1:50;
  then
A31: A >0 by XREAL_1:139;
  then
A32: (h.p2)`1>(h.p3)`1 by A10,A30,Th50;
  (g.O)`2= c by A4,A15;
  then
A33: ((g2).I)`1> -1 by A1,A9,A12,A15,A16,A21,Th67;
  h is being_homeomorphism by A31,A30,Th50;
  then
A34: h is one-to-one by TOPS_2:def 5;
A35: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A20,Th52;
A36: (h.p3)`1>(h.p4)`1 by A11,A31,A30,Th50;
A37: ((g2).I)`2= -1 by A2,A6,A16,Th57;
A38: ((g2).O)`2= -1 by A2,A4,A15,Th57;
  (g.I)`2= c by A6,A16;
  then
A39: 1 >=((g2).O)`1 by A1,A9,A12,A15,A16,A21,Th67;
A40: g2 is continuous one-to-one by A1,A2,A18,Th53;
A41: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then
A42: h.p4=g2.I by A16,FUNCT_1:13;
  h.p2=g2.O by A15,A41,FUNCT_1:13;
  then rng f2 meets rng g2 by A32,A36,A29,A42,A24,A23,A26,A22,A27,A25,A40,A38
,A37,A39,A33,A35,Th47,JGRAPH_6:79;
  then
A43: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A44: z2 in dom g2 and
A45: x=g2.z2 by FUNCT_1:def 3;
A46: x=h.(g.z2) by A41,A44,A45,FUNCT_1:13;
A47: g.z2 in rng g by A41,A44,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A44,FUNCT_2:5;
  then
A48: g.z2 in dom h by FUNCT_2:def 1;
  x in rng f2 by A43,XBOOLE_0:def 4;
  then consider z1 being object such that
A49: z1 in dom f2 and
A50: x=f2.z1 by FUNCT_1:def 3;
A51: f.z1 in rng f by A28,A49,FUNCT_1:def 3;
  f.z1 in the carrier of TOP-REAL 2 by A49,FUNCT_2:5;
  then
A52: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A28,A49,A50,FUNCT_1:13;
  then f.z1=g.z2 by A46,A52,A48,A34,FUNCT_1:def 4;
  hence thesis by A51,A47,XBOOLE_0:3;
end;
