
theorem Th136:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`2= c & p2`2=
c & p3`2= c & p4`2= c & b >=p1`1 & p1`1>p2`1 & p2`1>p3`1 & p3`1>p4`1 & p4`1> a
  & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one & g is
continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) & rng g c=
  closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`2= c and
A4: p2`2= c and
A5: p3`2= c and
A6: p4`2= c and
A7: b >=p1`1 and
A8: p1`1>p2`1 and
A9: p2`1>p3`1 and
A10: p3`1>p4`1 and
A11: p4`1> a and
A12: f.0=p1 and
A13: f.1=p3 and
A14: g.0=p2 and
A15: g.1=p4 and
A16: f is continuous one-to-one and
A17: g is continuous one-to-one and
A18: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A19: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A20: g2 is continuous one-to-one by A1,A2,A17,Th53;
A21: (g.O)`2= c by A4,A14;
A22: b>p2`1 by A7,A8,XXREAL_0:2;
  p2`1>p4`1 by A9,A10,XXREAL_0:2;
  then
A23: ((g2).I)`1> -1 by A1,A11,A14,A15,A22,A21,Th67;
A24: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A19,Th52;
A25: ((g2).I)`2= -1 by A2,A6,A15,Th57;
A26: ((g2).O)`2= -1 by A2,A4,A14,Th57;
A27: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then
A28: h.p2=g2.O by A14,FUNCT_1:13;
A29: h.p4=g2.I by A15,A27,FUNCT_1:13;
  d-c >0 by A2,XREAL_1:50;
  then
A30: C >0 by XREAL_1:139;
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A31: f2 is continuous one-to-one by A1,A2,A16,Th53;
A32: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A18,Th52;
A33: ((f2).I)`2= -1 by A2,A5,A13,Th57;
A34: (f.I)`2= c by A5,A13;
A35: p3`1>a by A10,A11,XXREAL_0:2;
  p1`1>p3`1 by A8,A9,XXREAL_0:2;
  then
A36: 1 >=((f2).O)`1 by A1,A7,A12,A13,A35,A34,Th67;
A37: ((f2).O)`2= -1 by A2,A3,A12,Th57;
  set x = the Element of rng f2 /\ rng g2;
A38: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A39: h.p3=f2.I by A13,FUNCT_1:13;
  b-a>0 by A1,XREAL_1:50;
  then
A40: A >0 by XREAL_1:139;
  then
A41: (h.p1)`1>(h.p2)`1 by A8,A30,Th50;
A42: (h.p3)`1>(h.p4)`1 by A10,A40,A30,Th50;
A43: (h.p2)`1>(h.p3)`1 by A9,A40,A30,Th50;
  h.p1=f2.O by A12,A38,FUNCT_1:13;
  then f2.O,g2.O,f2.I,g2.I are_in_this_order_on rectangle(-1,1,-1,1) by A41,A43
,A42,A28,A39,A29,A37,A33,A36,A26,A25,A23,Th48;
  then rng f2 meets rng g2 by A31,A32,A20,A24,JGRAPH_6:79;
  then
A44: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A45: z2 in dom g2 and
A46: x=g2.z2 by FUNCT_1:def 3;
A47: x=h.(g.z2) by A27,A45,A46,FUNCT_1:13;
  h is being_homeomorphism by A40,A30,Th51;
  then
A48: h is one-to-one by TOPS_2:def 5;
  x in rng f2 by A44,XBOOLE_0:def 4;
  then consider z1 being object such that
A49: z1 in dom f2 and
A50: x=f2.z1 by FUNCT_1:def 3;
A51: f.z1 in rng f by A38,A49,FUNCT_1:def 3;
A52: g.z2 in rng g by A27,A45,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A45,FUNCT_2:5;
  then
A53: g.z2 in dom h by FUNCT_2:def 1;
  f.z1 in the carrier of TOP-REAL 2 by A49,FUNCT_2:5;
  then
A54: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A38,A49,A50,FUNCT_1:13;
  then f.z1=g.z2 by A47,A54,A53,A48,FUNCT_1:def 4;
  hence thesis by A51,A52,XBOOLE_0:3;
end;
