
theorem
Sierp36 value(<%0,0%>^(11-->9)^<%1%>,10),100
proof
  set d=<%0,0%>^(11-->9)^<%1%>;
  A1: len d = len(<%0,0%>^(11-->9))+len<%1%> by AFINSQ_1:17
  .= len(<%0,0%>^(11-->9)) + 1 by AFINSQ_1:34;
  then A2: d.((len d)-1) = d.len(<%0,0%>^(11-->9));
  then A3: d.((len d)-1) > 0 by AFINSQ_1:36;
  A4:
  now
    let i be Nat;
    assume i in dom d;
    then d.i in rng d by FUNCT_1:3;
    then d.i in rng (<%0,0%>^(11-->9)) \/ rng <%1%> by AFINSQ_1:26;
    then d.i in rng <%0,0%> \/ rng (11-->9) \/ rng <%1%> by AFINSQ_1:26;
    then d.i in rng <%0,0%> \/ rng (11-->9) \/ {1} by AFINSQ_1:33;
    then d.i in {0,0} \/ rng (11-->9) \/ {1} by AFINSQ_1:98;
    then d.i in {0,0} \/ {9} \/ {1} by FUNCOP_1:8;
    then d.i in {0} \/ {9} \/ {1} by ENUMSET1:29;
    then d.i in {0,9} \/ {1} by ENUMSET1:1;
    then d.i in {0,9,1} by ENUMSET1:3;
    then d.i = 0 or d.i = 9 or d.i = 1 by ENUMSET1:def 1;
    hence d.i<10;
  end;
  A5: digits(value(d,10),10) = d by Th5,A3,A4;
  thus Sum digits(value(d,10),10) =
 Sum(<%0,0%>^(11-->9))+Sum <%1%> by AFINSQ_2:55,A5
  .= Sum(<%0,0%>^(11-->9))+1 by AFINSQ_2:53
  .= Sum<%0,0%>+Sum(11-->9)+1 by AFINSQ_2:55
  .= 0+0+Sum(11-->9)+1 by AFINSQ_2:54
  .= 0+0+(11*9)+1 by AFINSQ_2:58
  .= 100;
  then A6: Sum d=100 by Th5,A3,A4;
  consider d9 being XFinSequence of NAT such that
  A7:
  dom d9 = dom d &
  (for i being Nat st i in dom d9 holds d9.i = (d.i)*(10|^i))
  & value(d,10) = Sum d9 by NUMERAL1:def 1;
  A8: d=<%0,0%>^((11-->9)^<%1%>) by AFINSQ_1:27;
  now
    let i be Nat;
    assume A9: i in dom d9;
    per cases;
    suppose A10: i < 1+1;
      then i<=0+1 by NAT_1:9;
      then i<1 or i=1 by NAT_1:9;
      then A11: i=0 or i=1 by NAT_1:14;
      i < len <%0,0%> by A10,AFINSQ_1:38;
      then i in dom <%0,0%> by AFINSQ_1:86;
      then d.i=<%0,0%>.i by A8,ORDINAL4:def 1;
      then d.i=0 by A11;
      then d9.i=0*(10|^i) by A9,A7;
      hence 100 divides d9.i by NAT_D:6;
    end;
    suppose i >= 2;
      then reconsider i2=i-2 as Nat by NAT_1:21;
      d9.i=(d.i)*(10|^(i2+2)) by A9,A7
      .= (d.i)*(10|^(i2)*(10|^2)) by NEWTON:8
      .= (d.i)*(10|^(i2)*(10*10)) by POLYEQ_5:1
      .= 100*((d.i)*(10|^(i2)));
      hence 100 divides d9.i by INT_1:def 3;
    end;
  end;
  hence 100 divides value(d,10) by A7,NUMERAL2:16;
  let m be Nat;
  set dm=digits(m,10);
  set dm2=dm/^2;
  assume A12: Sum digits(m,10) = 100 & 100 divides m;
  then A13: dm.0=0 & dm.1=0 by Th13;
  A14:
  now
    assume m=0;
    then digits(m,10)=<%0%> by NUMERAL1:def 2;
    hence contradiction by A12,AFINSQ_2:53;
  end;
  assume m < value(d,10);
  then per cases by Th12;
  suppose
    len digits(m,10) < len digits(value(d,10),10);
    then len digits(m,10) < len d by Th5,A3,A4;
    then len digits(m,10) < len(<%0,0%>)+len(11-->9)+1 by A1,AFINSQ_1:17;
    then len digits(m,10) < 2+len(11-->9)+1 by AFINSQ_1:38;
    then A15: len dm < 14;
    now
      assume len dm < 3;
      then len dm in Segm 3 by NAT_1:44;
      then len dm in {0,1,2} by CARD_1:51;
      then per cases by ENUMSET1:def 1;
      suppose
        len dm = 0;
        hence contradiction by NUMERAL1:4;
      end;
      suppose
        len dm = 1;
        then dm.(1-1) <> 0 by NUMERAL1:def 2,A14;
        hence contradiction by Th13,A12;
      end;
      suppose
        len dm = 2;
        then dm.(2-1) <> 0 by NUMERAL1:def 2,A14;
        hence contradiction by Th13,A12;
      end;
    end;
    then len dm >= 2 by XXREAL_0:2;
    then <%dm.0,dm.1%>=dm|2 by Th14; then
    A16: dm=<%dm.0,dm.1%>^dm2;
    then len dm=len<%dm.0,dm.1%>+len dm2 by AFINSQ_1:17;
    then A17: len dm=2+len dm2 by AFINSQ_1:38;
    then 2+len dm2-2 < 14-2 by A15,XREAL_1:14;
    then len dm2 < 11+1;
    then len dm2 <= 11 by NAT_1:13;
    then A18: (len dm2)*9 <= 11*9 by XREAL_1:64;
    A19: Sum dm = Sum <%dm.0,dm.1%> + Sum dm2 by A16,AFINSQ_2:55
    .= dm.0 + dm.1 + Sum dm2 by AFINSQ_2:54
    .= 0 + dm.1 + Sum dm2 by Th13,A12
    .= 0 + Sum dm2 by Th13,A12;
    now
      let n be Nat;
      assume A20: n in dom dm2;
      then A21: dm2.n=dm.(n+2) by AFINSQ_2:def 2;
      n in Segm dom dm2 by A20;
      then n < len dm2 by NAT_1:44;
      then n+2 < len dm2 + 2 by XREAL_1:8;
      then n+2 in Segm dom dm by A17,NAT_1:44;
      then dm2.n < 9+1 by A14,A21,NUMERAL1:def 2;
      hence dm2.n<=9 by NAT_1:13;
    end;
    then Sum dm2 <= (len dm2) * 9 by AFINSQ_2:59;
    then Sum dm2 <= 11*9 by A18,XXREAL_0:2;
    hence contradiction by A12,A19;
  end;
  suppose
    A22: len digits(m,10) = len digits(value(d,10),10) &
    ex i being Nat st i < len digits(m,10) &
    digits(m,10).i < digits(value(d,10),10).i &
    for j being Nat st j < len digits(m,10) &
    digits(m,10).j <> digits(value(d,10),10).j holds i>=j;
    then A23: len dm = len d by Th5,A3,A4;

    consider i being Nat such that
    A24: i < len digits(m,10) &
    digits(m,10).i < digits(value(d,10),10).i &
    for j being Nat st j < len digits(m,10) &
    digits(m,10).j <> digits(value(d,10),10).j holds i>=j
    by A22;
    A25:
    now
      assume A26: i = len d-1;
      then d.i=1 by AFINSQ_1:36,A2;
      then dm.i = 0 by A5,A24,NAT_1:14;
      hence contradiction by A14,A26,A23,NUMERAL1:def 2;
    end;

    set dm1=dm|i;
    set dm2=dm/^i;
    set dmi=dm2|1;
    set dmi1=dm2/^1;
    dm=dm1^(dmi^dmi1);
    then Sum dm = Sum dm1 + Sum (dmi^dmi1) by AFINSQ_2:55;
    then A27: Sum dm = Sum dm1 + (Sum dmi + Sum dmi1) by AFINSQ_2:55;

    set d1=d|i;
    set d2=d/^i;
    set di=d2|1;
    set di1=d2/^1;
    d=d1^(di^di1);
    then Sum d = Sum d1 + Sum (di^di1) by AFINSQ_2:55;
    then A28: Sum d = Sum d1 + (Sum di + Sum di1) by AFINSQ_2:55;

    i < len d & i < len dm by A24,A5,A22; then
    A29: len d2 = len d - i & len dm2 = len dm - i by AFINSQ_2:7;

    i < len d by A5,A24,A22; then
    i+1 <= len d by NAT_1:13; then
    i+1 = len d or i+1 < len d by XXREAL_0:1; then
    i+1 < len d by A25; then
    i+1-i < len d - i by XREAL_1:9; then
    A30: 1 < len d2 by A29;
    then A31: len di1 = len d - i - 1 by A29,AFINSQ_2:7;
    d2 is non empty by A30;
    then A32: 0 in dom d2 by AFINSQ_1:65;

    i < len dm by A24; then
    i+1 <= len dm by NAT_1:13; then
    i+1 = len dm or i+1 < len dm by XXREAL_0:1; then
    i+1 < len dm by A25,A22,A5; then
    i+1-i < len dm - i by XREAL_1:9; then
    A33: 1 < len dm2 by A29;
    then A34: len dmi1 = len dm - i - 1 by A29,AFINSQ_2:7;
    dm2 is non empty by A33;
    then A35: 0 in dom dm2 by AFINSQ_1:65;
    A36:
    dom dmi1 = dom di1 by A31,A34,A22,A5;
    now
      let a be Nat;
      assume A37: a in dom dmi1;

      A38: dmi1.a = dm2.(a+1) & di1.a = d2.(a+1) by A36,A37,AFINSQ_2:def 2;

      a < len dm - i - 1 by A34,A37,AFINSQ_1:86;
      then A39: a+1 < len dm - i - 1 + 1 by XREAL_1:8;
      then a+1 < len dm2 by A29;
      then a+1 in dom dm2 by AFINSQ_1:86;
      then A40: dmi1.a = dm.(a+1+i) by A38,AFINSQ_2:def 2;

      a < len d - i - 1 by A22,A5,A34,A37,AFINSQ_1:86;
      then a+1 < len d - i - 1 + 1 by XREAL_1:8;
      then a+1 < len d2 by A29;
      then a+1 in dom d2 by AFINSQ_1:86;
      then A41: di1.a = d.(a+1+i) by A38,AFINSQ_2:def 2;

      set j=a+1+i;

      A42: j < len dm - i + i by A39,XREAL_1:8;
      j > 0+i by XREAL_1:8;
      hence dmi1.a <= di1.a by A41,A40,A42,A24,A5;
    end;
    then A43: Sum dmi1 <= Sum di1 by A36,AFINSQ_2:57;

    A44:
    dom dm1 = i by A24,AFINSQ_1:11 .= dom d1 by A24,AFINSQ_1:11,A23;
    now
      let a be Nat;
      assume A45: a in dom dm1;
      then a in Segm i by A24,AFINSQ_1:11;
      then A46: a < i by NAT_1:44;
      i < len(<%0,0%>^(11-->9)) + 1 by A24,A1,A22,A5;
      then i <= len(<%0,0%>^(11-->9)) by NAT_1:13;

      then a < Segm len(<%0,0%>^(11-->9)) by A46,XXREAL_0:2;
      then A47: a in dom(<%0,0%>^(11-->9)) by NAT_1:44;
      then A48: d.a = (<%0,0%>^(11-->9)).a by AFINSQ_1:def 3;
      per cases;
      suppose a<2;
        then a=0 or a=1 by NAT_1:23;
        then dm1.a = dm.0 or dm1.a=dm.1 by FUNCT_1:47,A45;
        hence dm1.a <= d1.a by A13;
      end;
      suppose a>=2;
        then a >= len <%0,0%> by AFINSQ_1:38;
        then not a in dom <%0,0%> by AFINSQ_1:86;
        then consider b being Nat such that
        A49: b in dom (11-->9) & a=len <%0,0%> + b by AFINSQ_1:20,A47;
        d.a = (11-->9).b by A48,A49,AFINSQ_1:def 3;
        then A50: d.a = 9 by A49,FUNCOP_1:7;
        dom dm1 c= dom dm by RELAT_1:60;
        then a in dom dm by A45;
        then dm.a < 9+1 by NUMERAL1:def 2,A14;
        then dm.a <= 9 by NAT_1:13;
        then dm.a <= d.a by A50;
        then dm.a <= d1.a by A44,A45,FUNCT_1:47;
        hence dm1.a <= d1.a by A45,FUNCT_1:47;
      end;
    end;
    then A51: Sum dm1 <= Sum d1 by A44,AFINSQ_2:57;

    dm2 is non empty by A33;
    then dmi=<%dm2.0%> by NUMERAL2:1;
    then dmi=<%dm.(i+0)%> by A35,AFINSQ_2:def 2;
    then A52: Sum dmi = dm.i by AFINSQ_2:53;
    d2 is non empty by A30;
    then di=<%d2.0%> by NUMERAL2:1;
    then di=<%d.(i+0)%> by A32,AFINSQ_2:def 2;
    then Sum dmi < Sum di by A52,A24,A5,AFINSQ_2:53;
    then Sum dmi + Sum dmi1 < Sum di + Sum di1 by A43,XREAL_1:8;
    then Sum dm < Sum d by A51,A27,A28,XREAL_1:8;
    hence contradiction by A6,A12;
  end;
end;
