reserve p,p1,p2,q,r,F,G,G1,G2,H,H1,H2 for ZF-formula,
  x,x1,x2,y,y1,y2,z,z1,z2,s,t for Variable,
  a,X for set;
reserve M for non empty set,
  m,m9 for Element of M,
  v,v9 for Function of VAR,M;
reserve i,j for Element of NAT;

theorem Th139:
  variables_in x 'in' y = {x,y}
proof
A1: rng (x 'in' y) = rng (<*1*>^<*x*>) \/ rng <*y*> by FINSEQ_1:31
    .= rng <*1*> \/ rng <*x*> \/ rng <*y*> by FINSEQ_1:31
    .= {1} \/ rng <*x*> \/ rng <*y*> by FINSEQ_1:39
    .= {1} \/ {x} \/ rng <*y*> by FINSEQ_1:39
    .= {1} \/ {x} \/ {y} by FINSEQ_1:39
    .= {1} \/ ({x} \/ {y}) by XBOOLE_1:4
    .= {1} \/ {x,y} by ENUMSET1:1;
  thus variables_in (x 'in' y) c= {x,y}
  proof
    let a be object;
    assume
A2: a in variables_in x 'in' y;
    then a <> 1 by Th137;
    then not a in {1} by TARSKI:def 1;
    hence thesis by A1,A2,XBOOLE_0:def 3;
  end;
  let a be object;
  assume
A3: a in {x,y};
  then a = x or a = y by TARSKI:def 2;
  then
A4: not a in {0,1,2,3,4} by Th136;
  a in {1} \/ {x,y} by A3,XBOOLE_0:def 3;
  hence thesis by A1,A4,XBOOLE_0:def 5;
end;
