reserve Omega for non empty set,
        Sigma for SigmaField of Omega,
        Prob for Probability of Sigma,
        A for SetSequence of Sigma,
        n,n1,n2 for Nat;

theorem Th13:
  Partial_Sums(Prob*A) is convergent implies
    (Prob.@lim_sup A = 0 & lim(Sum_Shift_Seq(Prob,A))=0 &
       Sum_Shift_Seq(Prob,A) is convergent)
proof
  assume A1: Partial_Sums(Prob*A) is convergent; then
A2: (Prob*A) is summable by SERIES_1:def 2;
A3: for n being Nat holds
     0<=(Prob*Partial_Intersection superior_setsequence A).n
    proof
    let n be Nat;
    dom(Prob*Partial_Intersection superior_setsequence A)=NAT by FUNCT_2:def 1;
     then (Prob*Partial_Intersection superior_setsequence A).n =
       Prob.((Partial_Intersection superior_setsequence A).n)
         by FUNCT_1:12,ORDINAL1:def 12;
     hence thesis by PROB_1:def 8;
    end;
A5: Intersection Partial_Intersection superior_setsequence A=
     Intersection superior_setsequence A by PROB_3:29;
    Partial_Intersection superior_setsequence A is non-ascending
      by PROB_3:27;then
A7: lim(Prob*Partial_Intersection superior_setsequence A) =
     Prob.Intersection Partial_Intersection superior_setsequence A &
     Prob*Partial_Intersection superior_setsequence A is convergent
    by PROB_1:def 8;
A8: for A being SetSequence of Sigma holds
      for n,s being Nat holds
       (Prob*(Partial_Union (A^\s))).n <= (Partial_Sums(Prob*(A^\s))).n
      proof
       let A be SetSequence of Sigma;
       let n,s be Nat;
       defpred P[set] means
         (Prob*(Partial_Union (A^\s))).$1 <= Partial_Sums(Prob*(A^\s)).$1;
       A9: Partial_Sums(Prob*(A^\s)).0 =
           (Prob*(A^\s)).0 by SERIES_1:def 1;
       dom(Prob*(A^\s))=NAT by FUNCT_2:def 1; then
       A11: (Prob*(A^\s)).0=Prob.((A^\s).0) by FUNCT_1:12;
       A12: Prob.((Partial_Union (A^\s)).0) = Prob.((A^\s).0) by PROB_3:def 2;
       dom(Prob*(Partial_Union (A^\s))) = NAT by FUNCT_2:def 1; then
       A14: P[0] by A12,A11,A9,FUNCT_1:12;
       A15: for k being Nat st P[k] holds P[k+1]
           proof
            let k be Nat;
            assume A16: (Prob*(Partial_Union (A^\s))).k
                         <= Partial_Sums(Prob*(A^\s)).k;
            A17: dom(Prob*(Partial_Union (A^\s))) = NAT by FUNCT_2:def 1;
            A18: Prob.((Partial_Union (A^\s)).k \/ (A^\s).(k+1)) <=
                 Prob.((Partial_Union (A^\s)).k) +
                  Prob.((A^\s).(k+1)) by PROB_1:39;
            dom(Prob*(A^\s))=NAT by FUNCT_2:def 1; then
            A19: (Prob*(A^\s)).(k+1) = Prob.((A^\s).(k+1)) by FUNCT_1:12;
            A20: Prob.((Partial_Union (A^\s)).(k+1)) <=
                 Prob.((Partial_Union (A^\s)).k) + (Prob*(A^\s)).(k+1) implies
                 Prob.((Partial_Union (A^\s)).(k+1)) -
                  Prob.((Partial_Union (A^\s)).k)
                 <= (Prob*(A^\s)).(k+1) by XREAL_1:20;
            A21: (Prob.((Partial_Union (A^\s)).(k+1)) - (Prob*(A^\s)).(k+1))
                 <= Prob.((Partial_Union (A^\s)).k) &
                 Prob.((Partial_Union (A^\s)).k)
                 <= Partial_Sums(Prob*(A^\s)).k implies
                 (Prob.((Partial_Union (A^\s)).(k+1)) - (Prob*(A^\s)).(k+1))
                 <= Partial_Sums(Prob*(A^\s)).k by XXREAL_0:2;
           A22: Prob.((Partial_Union (A^\s)).(k+1)) - (Prob*(A^\s)).(k+1)
                 <= Partial_Sums(Prob*(A^\s)).k implies
                 Prob.((Partial_Union (A^\s)).(k+1))
                 <= Partial_Sums(Prob*(A^\s)).k + (Prob*(A^\s)).(k+1)
      by XREAL_1:20;
A23: Prob.((Partial_Union (A^\s)).(k+1))
                       <= Partial_Sums(Prob*(A^\s)).(k+1)
      by A18,A19,A20,A17,A16,A21,A22,FUNCT_1:12,
         PROB_3:def 2,SERIES_1:def 1,XREAL_1:12,ORDINAL1:def 12;
           dom(Prob*(Partial_Union (A^\s))) = NAT by FUNCT_2:def 1;
           hence thesis by A23,FUNCT_1:12;
           end;
       for k being Nat holds P[k] from NAT_1:sch 2(A14,A15);
       hence thesis;
       end;
A24: for k being Nat holds
        Partial_Sums( (Prob*A) ^\k ) is convergent
        proof
          let k be Nat;
          (Prob*A) ^\ k is summable by A2,SERIES_1:12;
          hence thesis by SERIES_1:def 2;
        end;
A25: for A being SetSequence of Sigma holds
        for n being Nat holds (Prob*(A^\n))=( (Prob*A)^\n )
proof
 let A be SetSequence of Sigma;
 let n be Nat;
 for k being Element of NAT holds (Prob*(A^\n)).k=( (Prob*A)^\n ).k
 proof
  let k be Element of NAT;
  dom(Prob*(A^\n))=NAT by FUNCT_2:def 1; then
  A26: (Prob*(A^\n)).k =Prob.(((A^\n)).k) by FUNCT_1:12;
  dom(Prob*A)=NAT by FUNCT_2:def 1; then
  A27: Prob.(A.(n+k))=(Prob*A).(n+k) by FUNCT_1:12;
  (Prob*A).(k+n)=((Prob*A)^\n).k by NAT_1:def 3;
  hence thesis by A26,A27,NAT_1:def 3;
end;
 hence thesis;
end;
A28: for n being Nat holds Partial_Sums( Prob*(A^\n) ) is convergent
             proof
              let n be Nat;
              Partial_Sums( Prob*(A^\n) )=
               Partial_Sums( (Prob*A)^\n) by A25;
              hence thesis by A24;
             end;
A29: for n being Nat holds
             lim (Prob * Partial_Union (A^\n)) <=
             lim(Partial_Sums(Prob*(A^\n)))
             proof
              let n be Nat;
              A30: for k being Nat holds
              (Prob*(Partial_Union (A^\n))).k <=
                (Partial_Sums(Prob*(A^\n))).k by A8;
              A31: Prob*Partial_Union (A^\n) is convergent by PROB_3:41;
              Partial_Sums( Prob*(A^\n)) is convergent by A28;
              hence thesis by A31,A30,SEQ_2:18;
             end;
A32:         for n being Nat holds
              Prob.Union (A^\n) <= lim(Partial_Sums(Prob*(A^\n)))
             proof
              let n be Nat;
              lim (Prob * Partial_Union (A^\n)) <=
                   lim(Partial_Sums(Prob*(A^\n))) by A29;
              hence thesis by PROB_3:41;
             end;
A33:         for n being Nat holds
              Prob.Union (A^\n)<= Sum(Prob*(A^\n))
             proof
              let n be Nat;
              lim(Partial_Sums(Prob*(A^\n)))=
                  Sum(Prob*(A^\n)) by SERIES_1:def 3;
              hence thesis by A32;
             end;
A34: for n being Nat holds
              (Prob*(superior_setsequence A)).n <=Sum_Shift_Seq(Prob,A).n
             proof
              let n be Nat;
              dom(Prob*(superior_setsequence A))=NAT by FUNCT_2:def 1; then
              A36: (Prob*(superior_setsequence A)).n=
                   Prob.((superior_setsequence A).n)
                     by FUNCT_1:12,ORDINAL1:def 12;
              A37: Prob.Union (A^\n)<= Sum(Prob*(A^\n)) by A33;
              Sum(Prob*(A^\n))=Sum_Shift_Seq(Prob,A).n by Def11;
              hence thesis by Def7,A36,A37;
             end;
A38: 0<=lim(Prob*Partial_Intersection superior_setsequence A)
 by A7,A3,SEQ_2:17;
A39: Sum_Shift_Seq(Prob,A) is convergent implies
             lim(Prob*Partial_Intersection superior_setsequence A)
              <= lim(Sum_Shift_Seq(Prob,A))
             proof
              assume A40: Sum_Shift_Seq(Prob,A) is convergent;
          A41:for n being Nat holds
                  (Prob*(Partial_Intersection superior_setsequence A)).n
                    <= (Prob*(superior_setsequence A)).n
              proof
               let n be Nat;
               A42: Prob.((Partial_Intersection superior_setsequence A).n) <=
                    Prob.((superior_setsequence A).n) by PROB_1:34,PROB_3:23;
               A43: dom(Prob*(Partial_Intersection superior_setsequence A))=NAT
                    by FUNCT_2:def 1;
               dom(Prob*(superior_setsequence A))=NAT by FUNCT_2:def 1; then
               (Prob*(superior_setsequence A)).n=
                    Prob.((superior_setsequence A).n)
                      by FUNCT_1:12,ORDINAL1:def 12;
               hence thesis by A43,A42,FUNCT_1:12,ORDINAL1:def 12;
            end;
            lim(Prob*Partial_Intersection superior_setsequence A)
                <= lim(Sum_Shift_Seq(Prob,A))
               proof
                for n being Nat holds
                     (Prob*Partial_Intersection superior_setsequence A).n
                      <= Sum_Shift_Seq(Prob,A).n
                     proof
                      let n be Nat;
                      A47: (Prob*Partial_Intersection superior_setsequence A).n
                             <= (Prob*(superior_setsequence A)).n by A41;
                      (Prob*(superior_setsequence A)).n
                             <= Sum_Shift_Seq(Prob,A).n by A34;
                      hence thesis by A47,XXREAL_0:2;
                     end;
                hence thesis by A7,A40,SEQ_2:18;
               end;
      hence thesis;
      end;

for A being SetSequence of Sigma holds
Partial_Sums(Prob*A) is convergent implies
 (0=lim Sum_Shift_Seq(Prob,A) & Sum_Shift_Seq(Prob,A) is convergent)
proof
let A be SetSequence of Sigma;
assume A50: Partial_Sums(Prob*A) is convergent;
A52: for n being Nat holds
     Sum(Prob*A)-Sum((Prob*A)^\(n+1))=Partial_Sums(Prob*A).n
proof
let n be Nat;
Sum(Prob*A)-Sum((Prob*A)^\(n+1))=
Partial_Sums(Prob*A).n+Sum((Prob*A)^\(n+1))-Sum((Prob*A)^\(n+1))
 by A50,SERIES_1:15,def 2;
hence thesis;
end;

A53: for n,m being Nat holds
    |.(Partial_Sums(Prob*A)).m -(Partial_Sums(Prob*A)).n.|
    =|.(Sum_Shift_Seq(Prob,A)^\1).m
       -(Sum_Shift_Seq(Prob,A)^\1).n.|
proof
 let n,m be Nat;
 A54: Partial_Sums(Prob*A).m-Partial_Sums(Prob*A).n=
     Partial_Sums(Prob*A).m-(Sum(Prob*A)-Sum((Prob*A)^\(n+1))) by A52;
 Partial_Sums(Prob*A).m-Partial_Sums(Prob*A).n=
     (Sum(Prob*A)-Sum((Prob*A)^\(m+1)))-
     (Sum(Prob*A)-Sum((Prob*A)^\(n+1))) by A52,A54; then
 A56: (Partial_Sums(Prob*A).m-Partial_Sums(Prob*A).n)=
      (Sum((Prob*A)^\(n+1))-Sum((Prob*A)^\(m+1)));
 A57: for A being SetSequence of Sigma holds
         for n being Element of NAT holds (Prob*(A^\n))=( (Prob*A)^\n )
 proof
  let A be SetSequence of Sigma;
  let n be Element of NAT;
  for k being Element of NAT holds (Prob*(A^\n)).k=( (Prob*A)^\n ).k
  proof
   let k be Element of NAT;
   dom(Prob*(A^\n))=NAT by FUNCT_2:def 1; then
   A58: (Prob*(A^\n)).k =Prob.(((A^\n)).k) by FUNCT_1:12;
   dom(Prob*A)=NAT by FUNCT_2:def 1; then
   A59: Prob.(A.(n+k))=(Prob*A).(n+k) by FUNCT_1:12;
   (Prob*A).(k+n)=((Prob*A)^\n).k by NAT_1:def 3;
   hence thesis by A58,A59,NAT_1:def 3;
 end;
  hence thesis;
 end;
 A60: for n being Nat holds
       (Sum_Shift_Seq(Prob,A)^\1).n=Sum((Prob*A)^\(n+1))
 proof
  let n be Nat;
  A61:(Sum_Shift_Seq(Prob,A)^\1).n=Sum_Shift_Seq(Prob,A).(n+1)
        by NAT_1:def 3;
  Sum_Shift_Seq(Prob,A).(n+1)=Sum(Prob*(A^\(n+1)) ) by Def11;
  hence thesis by A57,A61;
 end;
 A62: |.(Partial_Sums(Prob*A)).m -(Partial_Sums(Prob*A)).n.|
     =|.(Sum_Shift_Seq(Prob,A)^\1).n -(Sum_Shift_Seq(Prob,A)^\1).m.|
 proof
  (Partial_Sums(Prob*A)).m -(Partial_Sums(Prob*A)).n=
  (Sum_Shift_Seq(Prob,A)^\1).n-Sum((Prob*A)^\(m+1)) by A56,A60;
  hence thesis by A60;
 end;
 |.(Sum_Shift_Seq(Prob,A)^\1).n-(Sum_Shift_Seq(Prob,A)^\1).m.|=
         |.(Sum_Shift_Seq(Prob,A)^\1).m-(Sum_Shift_Seq(Prob,A)^\1).n.|
 proof
  per cases;
  suppose (Sum_Shift_Seq(Prob,A)^\1).n-(Sum_Shift_Seq(Prob,A)^\1).m=0;
  hence thesis;
  end;
  suppose 0< (Sum_Shift_Seq(Prob,A)^\1).n-
                  (Sum_Shift_Seq(Prob,A)^\1).m; then
  A63:-0>-((Sum_Shift_Seq(Prob,A)^\1).n-(Sum_Shift_Seq(Prob,A)^\1).m);
  |.(Sum_Shift_Seq(Prob,A)^\1).m-
        (Sum_Shift_Seq(Prob,A)^\1).n.|=
      -((Sum_Shift_Seq(Prob,A)^\1).m- (Sum_Shift_Seq(Prob,A)^\1).n)
      by A63,ABSVALUE:def 1;
  hence thesis;
  end;
  suppose (Sum_Shift_Seq(Prob,A)^\1).n-
                  (Sum_Shift_Seq(Prob,A)^\1).m<0; then
   |.(Sum_Shift_Seq(Prob,A)^\1).n-
                  (Sum_Shift_Seq(Prob,A)^\1).m.|=
      -((Sum_Shift_Seq(Prob,A)^\1).n-
                  (Sum_Shift_Seq(Prob,A)^\1).m) by ABSVALUE:def 1;
  hence thesis;
  end;
  end;
 hence thesis by A62;
 end;
A65: (for sr being Real st
      0<sr ex n being Nat st
       for m being Nat st n<=m holds
    |.(Partial_Sums(Prob*A)).m -(Partial_Sums(Prob*A)).n.|<sr)
      implies
    (for sr being Real st 0<sr ex n being Nat st
       for m being Nat st n<=m holds
     |.(Sum_Shift_Seq(Prob,A)^\1).m-
        (Sum_Shift_Seq(Prob,A)^\1).n.|<sr)
proof
 assume A66: for sr being Real st 0<sr ex n being Nat st
              for m being Nat st n<=m holds
     |.(Partial_Sums(Prob*A)).m -(Partial_Sums(Prob*A)).n.|<sr;
 let sr be Real such that A67: 0<sr;
 consider n being Nat such that
 A68: for m being Nat st n<=m holds
      |.(Partial_Sums(Prob*A)).m -(Partial_Sums(Prob*A)).n.|<sr by A66,A67;
 take n;
 let m be Nat such that A69: n<=m;
 |.(Partial_Sums(Prob*A)).m -(Partial_Sums(Prob*A)).n.|=
 |.(Sum_Shift_Seq(Prob,A)^\1).m- (Sum_Shift_Seq(Prob,A)^\1).n.| by A53;
 hence thesis by A68,A69;
end;
A70: Partial_Sums(Prob*A) is convergent &
       (Sum_Shift_Seq(Prob,A)^\1) is convergent by A50,A65,SEQ_4:41;
A71: dom((Sum_Shift_Seq(Prob,A)^\1)+
 Partial_Sums(Prob*A))=NAT by FUNCT_2:def 1;
 consider B being Real_Sequence such that A72: B=
((Sum_Shift_Seq(Prob,A)^\1)+ Partial_Sums(Prob*A));
 reconsider SP = Sum(Prob*A) as Element of REAL by XREAL_0:def 1;
set B1 = NAT --> SP;
A74: for n being Nat holds B1.n=B.n
proof
 let n be Nat;
 A75: for n being Nat holds
       (Sum_Shift_Seq(Prob,A)^\1).n=Sum((Prob*A)^\(n+1))
 proof
  let n be Nat;
  A76: (Sum_Shift_Seq(Prob,A)^\1).n=Sum_Shift_Seq(Prob,A).(n+1)
       by NAT_1:def 3;
  A77: for A being SetSequence of Sigma holds
          for n being Element of NAT holds (Prob*(A^\n))=( (Prob*A)^\n )
  proof
   let A be SetSequence of Sigma;
   let n be Element of NAT;
   for k being Element of NAT holds (Prob*(A^\n)).k=( (Prob*A)^\n ).k
   proof
    let k be Element of NAT;
    dom(Prob*(A^\n))=NAT by FUNCT_2:def 1; then
    A78: (Prob*(A^\n)).k =Prob.(((A^\n)).k) by FUNCT_1:12;
    dom(Prob*A)=NAT by FUNCT_2:def 1; then
    A79: Prob.(A.(n+k))=(Prob*A).(n+k) by FUNCT_1:12;
    (Prob*A).(k+n)=((Prob*A)^\n).k by NAT_1:def 3;
    hence thesis by A78,A79,NAT_1:def 3;
  end;
   hence thesis;
  end;
  Sum_Shift_Seq(Prob,A).(n+1)=Sum(Prob*(A^\(n+1)) ) by Def11;
  hence thesis by A76,A77;
 end;
 A81: (Sum_Shift_Seq(Prob,A)^\1).n=Sum((Prob*A)^\(n+1)) by A75;
 Sum((Prob*A)) = Partial_Sums((Prob*A)).n + Sum((Prob*A)^\(n+1))
 by A50,SERIES_1:15,def 2; then
 B1.n = Partial_Sums((Prob*A)).n + (Sum_Shift_Seq(Prob,A)^\1).n
 by A81,FUNCOP_1:7,ORDINAL1:def 12;
hence thesis by A71,A72,VALUED_1:def 1,ORDINAL1:def 12;
end;
A82: lim B1 = lim B
 proof
   ex k being Nat st
   for n being Nat st k<=n holds B1.n=B.n
   proof
     take 1;
     thus thesis by A74;
   end;
   hence thesis by SEQ_4:19;
 end;
 A83: Sum(Prob*A)= B1.1 .= lim B by A82,SEQ_4:26;
 lim B= lim (Sum_Shift_Seq(Prob,A)^\1)+
         lim Partial_Sums((Prob*A)) by A72,A70,SEQ_2:6; then
 Sum(Prob*A)=lim (Sum_Shift_Seq(Prob,A)^\1)+
         Sum((Prob*A)) by A83,SERIES_1:def 3;
 hence thesis by A70,SEQ_4:21,22;
end;
hence thesis by A5,A7,A38,A39,A1;
end;
