
theorem Th13:
  for x1,x2,x3,x4 being object holds rng <*x1,x2,x3,x4*> = {x1,x2,x3,x4}
proof
  let x1,x2,x3,x4 be object;
  for y being object holds y in {x1,x2,x3,x4} iff
ex x being object st x in dom
  <*x1,x2,x3,x4*> & y = <*x1,x2,x3,x4*>.x
  proof
    let y be object;
    thus y in {x1,x2,x3,x4} implies
    ex x being object st x in dom <*x1,x2,x3,x4*>
    & y = <*x1,x2,x3,x4*>.x
    proof
A1:   dom <*x1,x2,x3,x4*> = {1,2,3,4} by FINSEQ_1:89,FINSEQ_3:2;
      assume
A2:   y in {x1,x2,x3,x4};
      per cases by A2,ENUMSET1:def 2;
      suppose
A3:     y=x1;
        take 1;
        thus 1 in dom <*x1,x2,x3,x4*> by A1,ENUMSET1:def 2;
        thus thesis by A3;
      end;
      suppose
A4:     y=x2;
        take 2;
        thus 2 in dom <*x1,x2,x3,x4*> by A1,ENUMSET1:def 2;
        thus thesis by A4;
      end;
      suppose
A5:     y=x3;
        take 3;
        thus 3 in dom <*x1,x2,x3,x4*> by A1,ENUMSET1:def 2;
        thus thesis by A5;
      end;
      suppose
A6:     y=x4;
        take 4;
        thus 4 in dom <*x1,x2,x3,x4*> by A1,ENUMSET1:def 2;
        thus thesis by A6;
      end;
    end;
    given x being object such that
A7: x in dom <*x1,x2,x3,x4*> and
A8: y = <*x1,x2,x3,x4*>.x;
    x in Seg 4 by A7,FINSEQ_1:89;
    then x=1 or x=2 or x=3 or x=4 by ENUMSET1:def 2,FINSEQ_3:2;
    then
    <*x1,x2,x3,x4*>.x = x1 or <*x1,x2,x3,x4*>.x = x2 or <*x1,x2,x3,x4*>.x
    = x3 or <*x1,x2,x3,x4*>.x = x4;
    hence thesis by A8,ENUMSET1:def 2;
  end;
  hence thesis by FUNCT_1:def 3;
end;
