reserve X for non empty set;
reserve Y for ComplexLinearSpace;
reserve f,g,h for Element of Funcs(X,the carrier of Y);
reserve a,b for Complex;
reserve u,v,w for VECTOR of CLSStruct(#Funcs(X,the carrier of Y), (FuncZero(X,
    Y)),FuncAdd(X,Y),FuncExtMult(X,Y)#);

theorem Th13:
  for X,Y be ComplexLinearSpace holds LinearOperators(X,Y) is linearly-closed
proof
  let X, Y be ComplexLinearSpace;
  set W = LinearOperators(X,Y);
A1: for c be Complex for v be VECTOR of ComplexVectSpace(the carrier of X,Y
  ) st v in W holds c * v in W
  proof
    let c be Complex;
    let v be VECTOR of ComplexVectSpace(the carrier of X,Y) such that
A2: v in W;
    c*v is LinearOperator of X,Y
    proof
      reconsider f=c*v as Function of X,Y by FUNCT_2:66;
A3:   f is homogeneous
      proof
        reconsider v9 = v as Element of Funcs(the carrier of X,the carrier of
        Y);
        let x be VECTOR of X, s be Complex;
A4:     v9 is LinearOperator of X,Y by A2,Def4;
A5:     f= (FuncExtMult(the carrier of X,Y)).[c,v9] by CLVECT_1:def 1;
        hence f.(s*x) =c*v9.(s*x) by Th2
          .=c*(s*(v9.x)) by A4,Def3
          .=c*s*v9.x by CLVECT_1:def 4
          .=s*(c*v9.x) by CLVECT_1:def 4
          .=s*f.x by A5,Th2;
      end;
      f is additive
      proof
        reconsider v9 = v as Element of Funcs(the carrier of X,the carrier of
        Y);
        let x,y be VECTOR of X;
A6:     v9 is LinearOperator of X,Y by A2,Def4;
A7:     f= (FuncExtMult(the carrier of X,Y)).[c,v9] by CLVECT_1:def 1;
        hence f.(x+y) = c*(v9.(x+y)) by Th2
          .=c*(v9.x+v9.y) by A6,VECTSP_1:def 20
          .=c*v9.x+c*v9.y by CLVECT_1:def 2
          .=f.x+c*v9.y by A7,Th2
          .=f.x+ f.y by A7,Th2;
      end;
      hence thesis by A3;
    end;
    hence thesis by Def4;
  end;
  for v,u be VECTOR of ComplexVectSpace(the carrier of X, Y) st v in
LinearOperators(X,Y) & u in LinearOperators(X,Y) holds v + u in LinearOperators
  (X,Y)
  proof
    let v,u be VECTOR of ComplexVectSpace(the carrier of X,Y) such that
A8: v in W and
A9: u in W;
    v+u is LinearOperator of X,Y
    proof
      reconsider f=v+u as Function of X,Y by FUNCT_2:66;
A10:  f is homogeneous
      proof
        reconsider v9 = v, u9 = u as Element of Funcs(the carrier of X,the
        carrier of Y);
        let x be VECTOR of X, s be Complex;
A11:    u9 is LinearOperator of X,Y by A9,Def4;
A12:    v9 is LinearOperator of X,Y by A8,Def4;
        thus f.(s*x) =u9.(s*x)+v9.(s*x) by LOPBAN_1:1
          .=(s*(u9.x))+v9.(s*x) by A11,Def3
          .=s*u9.x+s*v9.x by A12,Def3
          .=s*(u9.x+v9.x) by CLVECT_1:def 2
          .= s*f.x by LOPBAN_1:1;
      end;
      f is additive
      proof
        reconsider v9 = v, u9 = u as Element of Funcs(the carrier of X,the
        carrier of Y);
        let x,y be VECTOR of X;
A13:    u9 is LinearOperator of X,Y by A9,Def4;
A14:    v9 is LinearOperator of X,Y by A8,Def4;
        thus f.(x+y) =u9.(x+y)+v9.(x+y) by LOPBAN_1:1
          .=(u9.x+u9.y)+v9.(x+y) by A13,VECTSP_1:def 20
          .=u9.x+u9.y+(v9.x+v9.y) by A14,VECTSP_1:def 20
          .=u9.x+u9.y+v9.x+v9.y by RLVECT_1:def 3
          .=u9.x+v9.x+u9.y+v9.y by RLVECT_1:def 3
          .= f.x+ u9.y+v9.y by LOPBAN_1:1
          .= f.x+ (u9.y+v9.y) by RLVECT_1:def 3
          .= f.x+f.y by LOPBAN_1:1;
      end;
      hence thesis by A10;
    end;
    hence thesis by Def4;
  end;
  hence thesis by A1,CLVECT_1:def 7;
end;
