reserve i, x, I for set,
  A, B, M for ManySortedSet of I,
  f, f1 for Function;
reserve SF, SG for SubsetFamily of M;
reserve E, T for Element of Bool M;

theorem Th13:
  for SF being non empty SubsetFamily of M holds dom |.SF.| = I
proof
  let SF be non empty SubsetFamily of M;
  consider A being non empty functional set such that
A1: A = SF and
A2: dom |.SF.| = meet the set of all  dom x where x is Element of A  and
  for i st i in dom |.SF.| holds |.SF.|.i = the set of all
 x.i where x is Element of A
   by Def2;
  the set of all  dom x where x is Element of A  = {I}
  proof
    thus the set of all  dom x where x is Element of A  c= {I}
    proof
      let a be object;
      assume a in the set of all  dom x where x is Element of A ;
      then consider x being Element of A such that
A3:   a = dom x;
      x is Element of SF by A1;
      then a = I by A3,PARTFUN1:def 2;
      hence thesis by TARSKI:def 1;
    end;
    set x = the Element of A;
    let a be object;
    assume a in {I};
    then
A4: a = I by TARSKI:def 1;
    x is Element of SF by A1;
    then dom x = I by PARTFUN1:def 2;
    hence thesis by A4;
  end;
  hence thesis by A2,SETFAM_1:10;
end;
