
theorem Th13:
  for X being non empty set, Y being set st X is c=directed & Y c=
  union X & Y is finite ex Z being set st Z in X & Y c= Z
proof
  let X be non empty set, Y be set;
  set x = the Element of X;
  defpred P[Nat] means for Y being set st Y c= union X & Y is
  finite & card Y = $1 ex Z being set st Z in X & Y c= Z;
  assume
A1: X is c=directed;
A2: now
    let n be Nat;
    assume
A3: P[n];
    thus P[n+1]
    proof
      let Y be set;
      assume that
A4:   Y c= union X and
A5:   Y is finite and
A6:   card Y = n+1;
      reconsider Y9 = Y as non empty set by A6;
      set y = the Element of Y9;
A7:   Y\{y} c= union X by A4;
      y in Y;
      then consider Z9 being set such that
A8:   y in Z9 and
A9:   Z9 in X by A4,TARSKI:def 4;
A10:  n+1-1 = n by XCMPLX_1:26;
      {y} c= Y & card {y} = 1 by CARD_1:30,ZFMISC_1:31;
      then card (Y\{y}) = n by A5,A6,A10,CARD_2:44;
      then consider Z being set such that
A11:  Z in X and
A12:  Y\{y} c= Z by A3,A5,A7;
      consider V being set such that
A13:  Z \/ Z9 c= V and
A14:  V in X by A1,A11,A9,Th5;
      take V;
      thus V in X by A14;
      thus Y c= V
      proof
        let x be object;
A15:    x in {y} or not x in {y};
        assume x in Y;
        then x = y or x in Y\{y} by A15,TARSKI:def 1,XBOOLE_0:def 5;
        then x in Z \/ Z9 by A12,A8,XBOOLE_0:def 3;
        hence thesis by A13;
      end;
    end;
  end;
A16: P[ 0 ]
  proof
    let Y be set;
    assume that
    Y c= union X and
    Y is finite and
A17: card Y = 0;
    Y = {} by A17;
    then Y c= x;
    hence thesis;
  end;
A18: for n being Nat holds P[n] from NAT_1:sch 2(A16,A2);
  assume that
A19: Y c= union X and
A20: Y is finite;
  reconsider Y9 = Y as finite set by A20;
  card Y = card Y9;
  hence thesis by A18,A19;
end;
