reserve i,n,m for Nat,
  x,y,X,Y for set,
  r,s for Real;

theorem Th13:
  for T be non empty TopSpace for F be Subset-Family of T for S be
SetSequence of T st rng S c= F ex R be SetSequence of T st R is non-ascending &
( F is centered implies R is non-empty ) & ( F is open implies R is open ) & (
  F is closed implies R is closed ) &
for i holds R.i = meet {S.j where j is  Element of NAT: j <= i}
proof
  let T be non empty TopSpace;
  let F be Subset-Family of T;
  let S be SetSequence of T such that
A1: rng S c= F;
A2: for i holds {S.j where j is Element of NAT: j <= i} c= F
  proof
    let i;
    let x be object;
    assume x in {S.j where j is Element of NAT : j <= i};
    then consider j be Element of NAT such that
A3:  x=S.j & j<=i;
    dom S=NAT by FUNCT_2:def 1;
    then x in rng S by A3,FUNCT_1:def 3;
    hence thesis by A1;
  end;
  defpred P[object,object] means
for i st i=$1 holds $2=meet {S.j where j is Element
  of NAT:j<=i};
A4: for x being object st x in NAT
  ex y being object st y in bool(the carrier of T) & P[x,y]
  proof
    let x be object;
    assume x in NAT;
    then reconsider i=x as Element of NAT;
    set SS={S.j where j is Element of NAT:j<=i};
    SS c= F by A2;
    then reconsider SS as Subset-Family of T by XBOOLE_1:1;
    take meet SS;
    thus thesis;
  end;
  consider R be SetSequence of T such that
A5: for x being object st x in NAT holds P[x,R.x] from FUNCT_2:sch 1(A4);
  take R;
  now
    let i be Nat;
A6:  i in NAT by ORDINAL1:def 12;
    set SS={S.j where j is Element of NAT:j<=i};
    set S1={S.j where j is Element of NAT:j<=i+1};
A7: SS c= S1
    proof
      let x be object;
      assume x in SS;
      then consider j be Element of NAT such that
A8:   x=S.j and
A9:   j<=i;
      j<=i+1 by A9,NAT_1:13;
      hence thesis by A8;
    end;
A10: meet SS=R.i by A5,A6;
    S.0 in SS;
    then meet S1 c= meet SS by A7,SETFAM_1:6;
    hence R.(i+1) c= R.i by A5,A10;
  end;
  hence R is non-ascending by KURATO_0:def 3;
A11: for i holds {S.j where j is Element of NAT:j<=i} is finite
  proof
    deffunc F(set)=S.$1;
    let i;
    set SS={S.j where j is Element of NAT:j<=i};
A12: SS c= {F(j)where j is Element of NAT:j in i+1}
    proof
      let x be object;
      assume x in SS;
      then consider j be Element of NAT such that
A13:  x=S.j and
A14:  j<=i;
      j<i+1 by A14,NAT_1:13;
      then j in Segm(i+1) by NAT_1:44;
      hence thesis by A13;
    end;
A15: i+1 is finite;
    {F(j)where j is Element of NAT:j in i+1} is finite from FRAENKEL:sch
    21(A15);
    hence thesis by A12;
  end;
  thus F is centered implies R is non-empty
  proof
    assume
A16: F is centered;
    now
      let x be object;
      assume x in dom R;
      then reconsider i=x as Element of NAT;
      set SS={S.j where j is Element of NAT:j<=i};
A17:  S.0 in SS;
A18:  SS c= F by A2;
      SS is finite by A11;
      then meet SS<>{} by A16,A17,A18,FINSET_1:def 3;
      hence R.x is non empty by A5;
    end;
    hence thesis by FUNCT_1:def 9;
  end;
  thus F is open implies R is open
  proof
    assume
A19: F is open;
    let i;
    set SS={S.j where j is Element of NAT:j<=i};
A20: SS c= F by A2;
    then reconsider SS as Subset-Family of T by XBOOLE_1:1;
    SS is finite by A11;
    then
A21: meet SS is open by A19,A20,TOPS_2:11,20;
    i in NAT by ORDINAL1:def 12;
    hence thesis by A5,A21;
  end;
  thus F is closed implies R is closed
  proof
    assume
A22: F is closed;
    let i;
    set SS={S.j where j is Element of NAT:j<=i};
A23: i in NAT by ORDINAL1:def 12;
A24: SS c= F by A2;
    then reconsider SS as Subset-Family of T by XBOOLE_1:1;
    meet SS is closed by A22,A24,TOPS_2:12,22;
    hence thesis by A5,A23;
  end;
  let i;
  i in NAT by ORDINAL1:def 12;
  hence thesis by A5;
end;
